Arch Linux User Repository

I'll take over maintenance. But please report any issues you have in the comments!

I orphaned this package, since I've got not time and don't use anki anymore.

There is an error with the latest commit.

This PKGBUILD builds:

# Maintainer: Martin Dünkelmann<nc-duenkekl3@netcologne.de>
# Contributor: Shaoyu Tseng<zandimna@autistici.org>
# Contributor: Daniel Egeberg <daniel.egeberg@gmail.com
# Contributor: Sławomir Kowalski <suawekk+aur@gmail.com>
# Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Timm Preetz <timm@preetz.us>
# Contributor: Michael 'manveru' Fellinger <m.fellinger@gmail.com>
# Contributor: Dave Pretty <david dot pretty at gmail dot com>

pkgname=anki-git
pkgver=r8971.311e70822
pkgrel=1
pkgdesc="Helps you remember facts (like words/phrases in a foreign language) efficiently"
url="http://ankisrs.net/"
license=('AGPL3')
arch=('any')
provides=('anki')
conflicts=('anki' 'anki20' 'anki-official-binary-bundle')
depends=(
    # anki and aqt
    'python-beautifulsoup4'
    'python-requests'
    'python-wheel'

    # anki
    'python-pysocks' # requests[socks]
    'python-decorator'
    'python-protobuf'
    'python-orjson'
    'python-distro'
    'python-stringcase'

    # aqt
    'python-send2trash'
    'python-markdown'
    'python-jsonschema'
    'python-pyaudio'
    'python-pyqtwebengine'
    'python-flask'
    'python-flask-cors'
    'python-waitress'
    'python-pyqt5'
)
makedepends=(
    'git'
    'rsync'

    'bazel'
    'clang'

    'maturin'
    'rust'

    'python-pip'
    'python-mypy-protobuf'
    'npm'
    'typescript'
)
optdepends=(
    'lame: record sound'
    'mpv: play sound. prefered over mplayer'
    'mplayer: play sound'
)
source=(
    $pkgname::git+https://github.com/dae/anki.git

    #ankitects-anki-core-i18n-master.tar.gz::https://github.com/ankitects/anki-core-i18n/tarball/master
    #ankitects-anki-desktop-ftl-master.tar.gz::https://github.com/ankitects/anki-desktop-ftl/tarball/master
    #ankitects-anki-desktop-i18n-master.tar.gz::https://github.com/ankitects/anki-desktop-i18n/tarball/master
)
sha512sums=('SKIP')

pkgver() {
    cd "$pkgname"
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
    cd "$pkgname"

    # Disable foring a specific bazel version to build with
    rm .bazelversion

    # Put translations in place.
    #ln -sf "$srcdir"/ankitects-anki-core-i18n-*/ rslib/ftl/repo
    #ln -sf "$srcdir"/ankitects-anki-desktop-ftl-*/ qt/ftl/repo
    #ln -sf "$srcdir"/ankitects-anki-desktop-i18n-*/ qt/po/repo
}

build() {
    cd "$pkgname"

    export CC=/usr/bin/clang
    export CXX=/usr/bin/clang++
    ./scripts/build
}

package() {
    cd "$pkgname"
    PIP_CONFIG_FILE=/dev/null pip install --isolated --root="$pkgdir" --ignore-installed --no-deps bazel-bin/pylib/anki/anki-*.whl bazel-bin/qt/aqt/aqt-*.whl

    install -Dm755 qt/runanki.py "$pkgdir"/usr/bin/anki
    install -Dm644 qt/package/lin/anki.desktop "$pkgdir"/usr/share/applications/anki.desktop
    install -Dm644 qt/package/lin/anki.png "$pkgdir"/usr/share/pixmaps/anki.png
}

I had a similar problem to ivs_er's. During the bazel stage, my build kept failing with the following error:

FATAL: bazel crashed due to an internal error. Printing stack trace:
java.lang.ExceptionInInitializerError
        at com.google.devtools.build.lib.actions.ParameterFile.writeContent(ParameterFile.java:118)
        at com.google.devtools.build.lib.actions.ParameterFile.writeParameterFile(ParameterFile.java:111)
        at com.google.devtools.build.lib.analysis.actions.ParameterFileWriteAction$ParamFileWriter.writeOutputFile(ParameterFileWriteAction.java:175)
...

I have both jdk-openjdk (17.u35-1) and jdk11-openjdk (11.0.12.u7-1) installed. archlinux-java status indicates that java-17-openjdk from that first package is set as the default. I was able to fix the build problem by temporarily switching over to JDK11, using archlinux-java set java-11-openjdk.

(It seems this is not the only package suffering from this problem; I've had a similar problem with the same solution upon installing shattered-pixel-dungeon from the AUR, which needs to be compiled with java. I suppose with any java pkgbuilds just try switching your default JDK version and you'll likely fix the problem.)

Bazel needs java.

But using java 17 I have javac.

Package broken. First it requires javac to build, which is not present in current versions of java. After setting the version of java manually so that javac is on PATH it then says:

ERROR: anki-2.1.49-cp39-abi3-manylinux_2_28_x86_64.whl is not a supported wheel on this platform.

2021-09-02 10:57 Solved by removing jdk 16 and letting yay install jdk 11.

OK, @DarkShadow44 's way worked. Removing ~/.cache/bezel fixed it.

@ghorshy Just remove the old anki versions. Maybe the anki developers need to fix something.

Tried to update anki for few days but this error comes up:

ERROR: Cannot install anki 2.1.46 (from /home/manjaro/.cache/yay/anki-git/src/anki-git/bazel-bin/pylib/anki/anki-2.1.46-cp38-abi3-manylinux2014_x86_64.whl) and anki 2.1.47 (from /home/manjaro/.cache/yay/anki-git/src/anki-git/bazel-bin/pylib/anki/anki-2.1.47-cp38-abi3-manylinux2014_x86_64.whl) because these package versions have conflicting dependencies.

The conflict is caused by:
    The user requested anki 2.1.46 (from /home/manjaro/.cache/yay/anki-git/src/anki-git/bazel-bin/pylib/anki/anki-2.1.46-cp38-abi3-manylinux2014_x86_64.whl)
    The user requested anki 2.1.47 (from /home/manjaro/.cache/yay/anki-git/src/anki-git/bazel-bin/pylib/anki/anki-2.1.47-cp38-abi3-manylinux2014_x86_64.whl)

I tried to -Rns in yay but now I can't install this package at all.