Arch Linux User Repository

@ant0n et all, lets keep the comments here about packaging issues, general Brave usage issues should go in another forum to not clutter up this comment space. I'm deleting comments that have no relation to packaging. Grey areas like crashes that could be blamed on Arch can stay until proven otherwise, but things like how to configure Brave to handle popups or site X or whatever just don't belong here. Thanks for understanding.

Thanks a lot. I think I have it, but now that I see, the ARM64 builds seem to be for now only for nightly version. You should ask for it here:

https://aur.archlinux.org/packages/brave-nightly-bin

@alosarjos

I know visual-studio-code-bin supports multiple architectures in the same package. Perhaps that'd be a good reference?

Not sure on how it should be handled if om the same package. Do you know of any other package with support for both arquitectures so I can give it a look?

Hi, I am new to Arch and AUR, but I believe that Brave is compatible with ARM64 architecture now. (See this github issue: https://github.com/brave/brave-browser/issues/11836#issuecomment-1277715637).

Will it be much trouble to add the ARM64 build to this package?

@alosarjos, enjoy your vacation! Thanks for maintaining the package.

For anyone interested, here's an updated PKGBUILD for 1.44.105. The only lines I changed were the pkgver and the first checksum.

# Maintainer: Caleb Maclennan <caleb@alerque.com>
# Maintainer: José Miguel Sarasola <jmsaraur@gmail.com>
# Contributor: Như Bảo Trương <28810481+nhubaotruong@users.noreply.github.com>
# Contributor: Andrés Rodríguez <hello@andres.codes>
# Contributor: Jacob Mischka <jacob@mischka.me>
# Contributor: Manuel Mazzuola <origin.of@gmail.com>
# Contributor: Simón Oroño <simonorono@protonmail.com>
# Contributor: now-im <now im 627 @ gmail . com>
# Contributor: Giusy Digital <kurmikon at libero dot it>

# Version notes:
# `curl https://brave-browser-downloads.s3.brave.com/latest/release.version`

pkgname=brave-bin
pkgver=1.44.105
pkgrel=1
epoch=1
pkgdesc='Web browser that blocks ads and trackers by default (binary release)'
arch=(x86_64)
url=https://brave.com
license=(MPL2 BSD custom:chromium)
depends=(alsa-lib
         gtk3
         libxss
         nss
         ttf-font)
optdepends=('cups: Printer support'
            'libgnome-keyring: Enable GNOME keyring support'
            'libnotify: Native notification support')
provides=("${pkgname%-bin}=$pkgver" 'brave-browser')
conflicts=("${pkgname%-bin}")
options=(!strip)
source=("$pkgname-$pkgver.zip::https://github.com/brave/brave-browser/releases/download/v$pkgver/brave-browser-$pkgver-linux-amd64.zip"
        "$pkgname.sh"
        'brave-browser.desktop')
noextract=("$pkgname-$pkgver.zip")
sha256sums=('72776609db8a7699f295bc4ed8bc6d0d56725f6bffe35ed84ec93d57e4264087'
            'ba7d57a3328c68e6a78e49506af0e238936e823b2f463e8087c20fcf4300232a'
            'c07276b69c7304981525ecb022f92daf7ae125a4fb05ac3442157b50826e257a')

prepare() {
    mkdir -p brave
    bsdtar -xf "$pkgname-$pkgver.zip" -C brave
    chmod +x brave/brave
}

package() {
    install -dm0755 "$pkgdir/usr/lib"
    cp -a brave "$pkgdir/usr/lib/$pkgname"

    # allow firejail users to get the suid sandbox working
    chmod 4755 "$pkgdir/usr/lib/brave-bin/chrome-sandbox"

    install -Dm0755 "$pkgname.sh" "$pkgdir/usr/bin/brave"
    install -Dm0644 -t "$pkgdir/usr/share/applications/" "brave-browser.desktop"
    install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname/" brave/LICENSE
    pushd "$pkgdir/usr/"
    for size in 16x16 24x24 32x32 48x48 64x64 128x128 256x256; do
        install -Dm0644 "lib/$pkgname/product_logo_${size/x*/}.png" \
            "share/icons/hicolor/$size/apps/brave-desktop.png"
    done
}

Hi there!

Im on vacation for a few days and can't update the package. Hope alerque can update in the meanwhile. If not doing it manually should be pretty easy.

Im sorry for the inconvenience

There is an issue with version 1.43.88 if using Wayland where the menu is displayed on the top left corner. This is an upstream Chromium issue that can be followed here: https://bugs.chromium.org/p/chromium/issues/detail?id=1358794&q=wayland&can=2

@Adramyttium It's something related to your AUR helper / Connection- I can download from that URL just fine.