first commit

2 files changed, 153 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..7aba1bf152c9
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,39 @@
+pkgbase = 3dslicer-git
+	pkgdesc = A free, open source and multi-platform software package widely used for medical, biomedical, and related imaging research
+	pkgver = 4.13.r27813.dcd132b264
+	pkgrel = 1
+	url = https://www.slicer.org
+	arch = x86_64
+	license = BSD
+	makedepends = cmake
+	makedepends = gendesk
+	makedepends = git
+	makedepends = subversion
+	depends = bzip2
+	depends = curl
+	depends = dcmtk
+	depends = libarchive
+	depends = libffi
+	depends = libxt
+	depends = openssl
+	depends = qt5-base
+	depends = qt5-multimedia
+	depends = qt5-script
+	depends = qt5-svg
+	depends = qt5-tools
+	depends = qt5-webengine
+	depends = qt5-x11extras
+	depends = qt5-xmlpatterns
+	depends = rapidjson
+	depends = sqlite
+	depends = teem
+	provides = 3dslicer=4.13.r27813.dcd132b264
+	conflicts = 3dslicer
+	options = !emptydirs
+	options = !strip
+	source = 3dslicer::git+https://github.com/Slicer/Slicer.git
+	source = 3dslicer.svg::https://www.slicer.org/assets/img/3D-Slicer-Mark.svg
+	sha512sums = SKIP
+	sha512sums = 3422d244f819a7ec4c475d3d8a90c79fcb73738920c0830b100c6342ca24d5be607ba60ee3d91892402036a0adf31d5ab7c8fc83f451121a7b537f7de5306014
+
+pkgname = 3dslicer-git
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..2a4998bd4337
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,114 @@
+# Maintainer: Butui Hu <hot123tea123@gmail.com>
+
+_pkgname=3dslicer
+pkgname=3dslicer-git
+_pkgver=5.1.0
+pkgver=4.13.r27813.dcd132b264
+pkgrel=1
+pkgdesc='A free, open source and multi-platform software package widely used for medical, biomedical, and related imaging research'
+arch=('x86_64')
+url='https://www.slicer.org'
+license=('BSD')
+depends=(
+  bzip2
+  curl
+  dcmtk
+  libarchive
+  libffi
+  libxt
+  openssl
+  qt5-base
+  qt5-multimedia
+  qt5-script
+  qt5-svg
+  qt5-tools
+  qt5-webengine
+  qt5-x11extras
+  qt5-xmlpatterns
+  rapidjson
+  sqlite
+  teem
+)
+makedepends=(
+  cmake
+  gendesk
+  git
+  subversion
+)
+options=(!emptydirs !strip)
+provides=(3dslicer=${pkgver})
+conflicts=(3dslicer)
+source=("${_pkgname}::git+https://github.com/Slicer/Slicer.git"
+        "${_pkgname}.svg::https://www.slicer.org/assets/img/3D-Slicer-Mark.svg"
+)
+sha512sums=('SKIP'
+            '3422d244f819a7ec4c475d3d8a90c79fcb73738920c0830b100c6342ca24d5be607ba60ee3d91892402036a0adf31d5ab7c8fc83f451121a7b537f7de5306014')
+
+pkgver() {
+  cd "${srcdir}/${_pkgname}"
+  ver=$(printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)")
+  echo "${_pkgver}.${ver}"
+}
+
+prepare() {
+  echo "Creating desktop file"
+  gendesk -f -n --pkgname ${_pkgname} \
+    --categories "Graphics;MedicalSoftware;Science;" \
+    --exec "Slicer" \
+    --icon "${_pkgname}" \
+    --pkgdesc "${pkgdesc}"
+  # find sqlite with cmake's FindSQLite3
+  sed -i 's/find_package(${proj} REQUIRED)/find_package(SQLite3 REQUIRED)/' "${srcdir}/${_pkgname}/SuperBuild/External_sqlite.cmake"
+  # fix building with system teem
+  sed -i '/ExternalProject_Add_Empty/d' "${srcdir}/${_pkgname}/SuperBuild/External_teem.cmake"
+}
+
+build() {
+  cmake -B build -S "${srcdir}/${_pkgname}" \
+    -DBUILD_TESTING=OFF \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DSlicer_BUILD_DOCUMENTATION=OFF \
+    -DSlicer_BUILD_I18N_SUPPORT=ON \
+    -DSlicer_STORE_SETTINGS_IN_APPLICATION_HOME_DIR=OFF \
+    -DSlicer_USE_GIT_PROTOCOL=OFF \
+    -DSlicer_USE_SYSTEM_CTK=OFF \
+    -DSlicer_USE_SYSTEM_CTKAPPLAUNCHER=OFF \
+    -DSlicer_USE_SYSTEM_CTKAppLauncherLib=OFF \
+    -DSlicer_USE_SYSTEM_CTKResEdit=OFF \
+    -DSlicer_USE_SYSTEM_DCMTK=ON \
+    -DSlicer_USE_SYSTEM_ITK=OFF \
+    -DSlicer_USE_SYSTEM_JsonCpp=OFF \
+    -DSlicer_USE_SYSTEM_LZMA=ON \
+    -DSlicer_USE_SYSTEM_LibArchive=ON \
+    -DSlicer_USE_SYSTEM_LibFFI=ON \
+    -DSlicer_USE_SYSTEM_OpenSSL=ON \
+    -DSlicer_USE_SYSTEM_PCRE=OFF \
+    -DSlicer_USE_SYSTEM_ParameterSerializer=OFF \
+    -DSlicer_USE_SYSTEM_QT=ON \
+    -DSlicer_USE_SYSTEM_RapidJSON=ON \
+    -DSlicer_USE_SYSTEM_SimpleITK=OFF \
+    -DSlicer_USE_SYSTEM_SlicerExecutionModel=OFF \
+    -DSlicer_USE_SYSTEM_Swig=OFF \
+    -DSlicer_USE_SYSTEM_VTK=OFF \
+    -DSlicer_USE_SYSTEM_bzip2=ON \
+    -DSlicer_USE_SYSTEM_curl=ON \
+    -DSlicer_USE_SYSTEM_qRestAPI=OFF \
+    -DSlicer_USE_SYSTEM_sqlite=ON \
+    -DSlicer_USE_SYSTEM_tbb=OFF \
+    -DSlicer_USE_SYSTEM_teem=ON \
+    -DSlicer_USE_SYSTEM_zlib=ON \
+    -DSlicer_USE_SimpleITK=ON \
+    -DSlicer_USE_SimpleITK_SHARED=ON
+  make -C "build"
+}
+
+package() {
+  make -C "${srcdir}/build/Slicer-build" package
+  install -d "${pkgdir}/opt/${_pkgname}" "${pkgdir}/usr/bin"
+  tar xvf "${srcdir}/build/Slicer-build/"*.tar.gz -C "${pkgdir}/opt/${_pkgname}" --strip-components 1
+  ln -s /opt/${_pkgname}/Slicer "${pkgdir}/usr/bin"
+  install -Dm644 "${srcdir}/${_pkgname}.desktop" "${pkgdir}/usr/share/applications/${_pkgname}.desktop"
+  install -Dm644 "${srcdir}/${_pkgname}.svg" "${pkgdir}/usr/share/pixmaps/${_pkgname}.svg"
+}
+# vim:set ts=2 sw=2 et: