initial version

3 files changed, 83 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..a61d6f22d92a
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,27 @@
+pkgbase = afterstep-git
+	pkgdesc = A Window Manager based on NextStep Interface
+	pkgver = 2.2.12.r18.g4f62e0d
+	pkgrel = 1
+	url = http://www.afterstep.org
+	arch = i686
+	arch = x86_64
+	license = GPL
+	makedepends = libxt
+	depends = gtk2>=2.18.6
+	depends = libpng
+	depends = libtiff
+	depends = readline
+	depends = freetype2
+	depends = dbus-core
+	depends = librsvg
+	provides = afterstep
+	conflicts = afterstep
+	options = !emptydirs
+	options = staticlibs
+	source = afterstep::git+https://github.com/sashavasko/afterstep-devel.git
+	source = desktop_entry.patch
+	md5sums = SKIP
+	md5sums = 90cb380546b5d64208f13ab4f473f56d
+
+pkgname = afterstep-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..16b12fd67223
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,45 @@
+# Maintainer: Brian Bidulock <bidulock@openss7.org>
+
+pkgname=afterstep-git
+_name=AfterStep
+_pkgname=afterstep
+pkgver=2.2.12.r18.g4f62e0d
+pkgrel=1
+pkgdesc="A Window Manager based on NextStep Interface"
+arch=('i686' 'x86_64')
+url="http://www.afterstep.org"
+license=('GPL')
+depends=('gtk2>=2.18.6' 'libpng' 'libtiff' 'readline' 'freetype2' 'dbus-core' 'librsvg')
+makedepends=('libxt')
+provides=("$_pkgname")
+conflicts=("$_pkgname")
+options=('!emptydirs' 'staticlibs')
+source=("$_pkgname::git+https://github.com/sashavasko/afterstep-devel.git"
+        desktop_entry.patch)
+md5sums=('SKIP'
+         '90cb380546b5d64208f13ab4f473f56d')
+
+pkgver() {
+  cd $_pkgname
+  git describe --long --tags | sed -E 's/([^-]*-g)/r\1/;s/-/./g'
+}
+
+prepare() {
+  cd $_pkgname
+  patch -p0 -i ../desktop_entry.patch
+}
+
+build() {
+  cd $_pkgname
+  ./configure --prefix=/usr --mandir=/usr/share/man
+  make V=0
+}
+
+package() {
+  cd $_pkgname
+  make DESTDIR="$pkgdir" install
+  install -Dm644 $_name.desktop "$pkgdir/usr/share/xsessions/$_name.desktop"
+  
+  # fix permission
+  chmod 644 "$pkgdir"/usr/lib/*.a
+}
diff --git a/desktop_entry.patch b/desktop_entry.patch
new file mode 100644
index 000000000000..4a6dd9987559
--- /dev/null
+++ b/desktop_entry.patch
@@ -0,0 +1,11 @@
+--- AfterStep.desktop.in	2014-03-25 13:12:02.882076891 +0100
++++ AfterStep.desktop.in.new	2014-03-25 13:15:38.652083555 +0100
+@@ -4,6 +4,8 @@
+ [Desktop Entry]
+ Name=AfterStep
+ Type=Application
++Exec=/usr/bin/afterstep
++TryExec=/usr/bin/afterstep
+ Comment=AfterStep is feature rich NeXTish window manager.
+ # name we put on the WM spec check window
+ X-GNOME-WMName=AfterStep