Initial import

2 files changed, 61 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..0f789884f37b
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,21 @@
+pkgbase = akonadi-calendar-git
+	pkgdesc = Akonadi calendar integration
+	pkgver = r1297.8b49a7c
+	pkgrel = 1
+	url = https://projects.kde.org/projects/kde/pim/akonadi-calendar
+	arch = i686
+	arch = x86_64
+	license = LGPL
+	makedepends = extra-cmake-modules-git
+	makedepends = kdoctools
+	makedepends = git
+	makedepends = python
+	depends = kmailtransport-git
+	depends = kcalutils-git
+	provides = akonadi-calendar
+	conflicts = akonadi-calendar
+	source = git://anongit.kde.org/akonadi-calendar.git
+	md5sums = SKIP
+
+pkgname = akonadi-calendar-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..b4f0fc238a98
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,40 @@
+# Maintainer: Antonio Rojas <arojas@archlinux.org>
+
+_gitname=akonadi-calendar
+pkgname=$_gitname-git
+pkgver=r1297.8b49a7c
+pkgrel=1
+pkgdesc="Akonadi calendar integration"
+arch=('i686' 'x86_64')
+url="https://projects.kde.org/projects/kde/pim/$_gitname"
+license=('LGPL')
+depends=('kmailtransport-git' 'kcalutils-git')
+makedepends=('extra-cmake-modules-git' 'kdoctools' 'git' 'python')
+conflicts=("$_gitname")
+provides=("$_gitname")
+source=("git://anongit.kde.org/$_gitname.git")
+md5sums=('SKIP')
+
+pkgver() {
+  cd $_gitname
+  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+prepare() {
+  mkdir -p build
+}
+
+build() {
+  cd build
+  cmake ../$_gitname \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=lib \
+    -DKDE_INSTALL_USE_QT_SYS_PATHS=ON
+  make
+}
+
+package() {
+  cd build
+  make DESTDIR="$pkgdir" install
+}