[add] alephone-git

2 files changed, 92 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..ad18c834f723
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,32 @@
+pkgbase = alephone-git
+	pkgdesc = A free, enhanced port of the classic FPS "Marathon 2" by Bungie Software (development version)
+	pkgver = 1.3a2.r4938.7d24fec4
+	pkgrel = 1
+	url = https://alephone.lhowon.org/
+	arch = i686
+	arch = x86_64
+	license = GPL3
+	makedepends = boost
+	makedepends = mesa
+	makedepends = icoutils
+	depends = sdl2_ttf
+	depends = sdl2_image
+	depends = sdl2_net
+	depends = libmad
+	depends = glu
+	depends = zziplib
+	depends = ffmpeg
+	depends = boost-libs
+	depends = curl
+	optdepends = alephone-eternalx: community-made scenario
+	optdepends = alephone-evil: community-made scenario
+	optdepends = alephone-infinity: original data for Marathon Infinity
+	optdepends = alephone-marathon: M1A1 data converted for AlephOne
+	optdepends = alephone-marathon2: original data for Marathon 2: Durandal
+	provides = alephone
+	conflicts = alephone
+	source = git+https://github.com/Aleph-One-Marathon/alephone
+	md5sums = SKIP
+
+pkgname = alephone-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..8be558849940
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,60 @@
+# Maintainer: carstene1ns <arch carsten-teibes de> - http://git.io/ctPKG
+
+pkgname=alephone-git
+pkgver=1.3a2.r4938.7d24fec4
+pkgrel=1
+pkgdesc='A free, enhanced port of the classic FPS "Marathon 2" by Bungie Software (development version)'
+arch=('i686' 'x86_64')
+url="https://alephone.lhowon.org/"
+license=('GPL3')
+conflicts=("alephone")
+provides=("alephone")
+depends=('sdl2_ttf' 'sdl2_image' 'sdl2_net' 'libmad' 'glu' 'zziplib' 'ffmpeg'
+         'boost-libs' 'curl')
+optdepends=('alephone-eternalx: community-made scenario'
+            'alephone-evil: community-made scenario'
+            'alephone-infinity: original data for Marathon Infinity'
+            'alephone-marathon: M1A1 data converted for AlephOne'
+            'alephone-marathon2: original data for Marathon 2: Durandal')
+makedepends=('boost' 'mesa' 'icoutils')
+source=("git+https://github.com/Aleph-One-Marathon/alephone")
+md5sums=('SKIP')
+
+pkgver() {
+  cd alephone/Source_Files/Misc
+
+  local _ver="$(grep '^#define A1_DISPLAY_VERSION' alephversion.h | cut -d\" -f2)"
+  printf "%s.r%s.%s" "$_ver" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+prepare() {
+  cd alephone
+
+  # convert the windows icons
+  cd Resources/Windows
+  icotool -x -w 48 alephone.ico -o "$srcdir"/alephone.png
+  icotool -x -w 48 marathon.ico -o "$srcdir"/alephone-marathon.png
+  icotool -x -w 48 marathon2.ico -o "$srcdir"/alephone-marathon2.png
+  icotool -x -w 48 marathon-infinity.ico -o "$srcdir"/alephone-infinity.png
+}
+
+build() {
+  cd alephone
+  
+  ./autogen.sh --prefix=/usr --without-smpeg
+  make
+}
+
+package() {
+  cd alephone
+
+  make DESTDIR="$pkgdir/" install
+
+  # icons
+  install -d "$pkgdir"/usr/share/icons
+  install -m644 "$srcdir"/*.png "$pkgdir"/usr/share/icons
+
+  # docs
+  install -Dm644 README "$pkgdir"/usr/share/doc/alephone/README
+  install -m644 docs/*.html "$pkgdir"/usr/share/doc/alephone
+}