Initial upload: ali-git 0.2.2.r0.g2ea1f4b-1

2 files changed, 52 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..79d8ed82501d
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,16 @@
+pkgbase = ali-git
+	pkgdesc = Generate HTTP load and plot the results in real-time (git)
+	pkgver = 0.2.2.r0.g2ea1f4b
+	pkgrel = 1
+	url = https://github.com/nakabonne/ali
+	arch = x86_64
+	license = MIT
+	makedepends = git
+	makedepends = go
+	conflicts = ali
+	conflicts = ali-bin
+	source = git+https://github.com/nakabonne/ali
+	sha256sums = SKIP
+
+pkgname = ali-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..5f55577d963a
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,36 @@
+# Maintainer: orhun <orhunparmaksiz@gmail.com>
+# https://github.com/orhun/pkgbuilds
+
+pkgname=ali-git
+pkgdesc="Generate HTTP load and plot the results in real-time (git)"
+pkgver=0.2.2.r0.g2ea1f4b
+pkgrel=1
+arch=('x86_64')
+url="https://github.com/nakabonne/ali"
+license=('MIT')
+makedepends=('git' 'go')
+conflicts=("${pkgname%-git}" "${pkgname%-git}-bin")
+source=("git+$url")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd "$srcdir/${pkgname%-git}"
+  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+  cd "$srcdir/${pkgname%-git}"
+  go get -d ./...
+  go build \
+    -gcflags "all=-trimpath=$PWD" \
+    -asmflags "all=-trimpath=$PWD" \
+    -ldflags "-extldflags $LDFLAGS" \
+    -o "${pkgname%-git}" .
+}
+
+package() {
+  cd "$srcdir/${pkgname%-git}"
+  install -Dm 755 "${pkgname%-git}" -t "$pkgdir/usr/bin"
+  install -Dm 644 README.md -t "$pkgdir/usr/share/doc/${pkgname%-git}"
+  install -Dm 644 LICENSE -t "$pkgdir/usr/share/licenses/${pkgname%-git}"
+}