Initialize

2 files changed, 69 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..c50d9ccf4b3b
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,21 @@
+pkgbase = app-icon-preview-git
+	pkgdesc = Tool for designing applications icons
+	pkgver = 2.1.2.r17.g37c7475
+	pkgrel = 1
+	url = https://gitlab.gnome.org/World/design/app-icon-preview
+	arch = x86_64
+	arch = aarch64
+	license = GPL3
+	makedepends = git
+	makedepends = meson
+	makedepends = rust
+	depends = libhandy0
+	provides = app-icon-preview
+	conflicts = app-icon-preview
+	source = git+https://gitlab.gnome.org/World/design/app-icon-preview.git
+	source = git+https://gitlab.gnome.org/Teams/Design/HIG-app-icons.git
+	sha256sums = SKIP
+	sha256sums = SKIP
+
+pkgname = app-icon-preview-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..dbc93014a12f
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,48 @@
+# Maintainer: Philip Goto <philip.goto@gmail.com>
+
+pkgname=app-icon-preview-git
+pkgver=2.1.2.r17.g37c7475
+pkgrel=1
+pkgdesc='Tool for designing applications icons'
+arch=(x86_64 aarch64)
+url='https://gitlab.gnome.org/World/design/app-icon-preview'
+license=(GPL3)
+depends=(libhandy0)
+makedepends=(
+	git
+	meson
+	rust
+)
+provides=(app-icon-preview)
+conflicts=(app-icon-preview)
+source=(
+	"git+${url}.git"
+	"git+https://gitlab.gnome.org/Teams/Design/HIG-app-icons.git"
+)
+sha256sums=('SKIP' 'SKIP')
+
+prepare() {
+	cd app-icon-preview
+
+	git submodule init
+	git config 'submodule.hig.url' "${srcdir}/HIG-app-icons"
+	git submodule update
+}
+
+pkgver() {
+	cd app-icon-preview
+	git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+	arch-meson app-icon-preview build
+	meson compile -C build
+}
+
+check() {
+	meson test -C build --print-errorlogs
+}
+
+package() {
+	DESTDIR="${pkgdir}" meson install -C build
+}