Batman! (this commit has no parents)

3 files changed, 72 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..00cc9772fe21
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,15 @@
+pkgbase = aptakube-appimage
+	pkgdesc = A modern and lightweight Kubernetes desktop client to help you operate workloads on multiple clusters.
+	pkgver = 0.6.1
+	pkgrel = 1
+	url = https://aptakube.com/
+	arch = x86_64
+	license = Proprietary
+	depends = zlib
+	depends = hicolor-icon-theme
+	noextract = aptakube-appimage-0.6.1.AppImage
+	options = !strip
+	source_x86_64 = aptakube-appimage-0.6.1.AppImage::https://releases.aptakube.com/aptakube_0.6.1_amd64.AppImage
+	sha256sums_x86_64 = 7d84ec8246600ab0906812bbf1cc1297f34991ec0a7a36b9c6649658409264cd
+
+pkgname = aptakube-appimage
diff --git a/.gitignore b/.gitignore
new file mode 100644
index 000000000000..1eca835fa363
--- /dev/null
+++ b/.gitignore
@@ -0,0 +1,4 @@
+/pkg
+/src
+/*.AppImage
+*.pkg.*
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..67819ca7a55b
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,53 @@
+# Maintainer: Borhaneddine GUEMIDI <guemidi borhane at aina dot dz>
+# Based on the template from https://daveparrish.net/posts/2019-11-16-Better-AppImage-PKGBUILD-template.html
+
+_pkgname=aptakube
+
+pkgname="${_pkgname}"-appimage
+pkgver=0.6.1
+pkgrel=1
+pkgdesc="A modern and lightweight Kubernetes desktop client to help you operate workloads on multiple clusters. (free to use during the public preview)"
+arch=('x86_64')
+url="https://aptakube.com/"
+license=('Proprietary')
+depends=('zlib' 'hicolor-icon-theme')
+options=(!strip)
+_appimage="${pkgname}-${pkgver}.AppImage"
+source_x86_64=("${_appimage}::https://releases.aptakube.com/${_pkgname}_${pkgver}_amd64.AppImage")
+noextract=("${_appimage}")
+sha256sums_x86_64=('7d84ec8246600ab0906812bbf1cc1297f34991ec0a7a36b9c6649658409264cd')
+
+prepare() {
+    chmod +x "${_appimage}"
+    ./"${_appimage}" --appimage-extract
+}
+
+build() {
+    # Adjust .desktop so it will work outside of AppImage container
+    sed -i -E "s|Exec=AppRun|Exec=env DESKTOPINTEGRATION=false /usr/bin/${_pkgname}|"\
+        "squashfs-root/${_pkgname}.desktop"
+    # Fix permissions; .AppImage permissions are 700 for all directories
+    chmod -R a-x+rX squashfs-root/usr
+}
+
+package() {
+    # AppImage
+    install -Dm755 "${srcdir}/${_appimage}" "${pkgdir}/opt/${pkgname}/${pkgname}.AppImage"
+    # install -Dm644 "${srcdir}/LICENSE" "${pkgdir}/opt/${pkgname}/LICENSE"
+
+    # Desktop file
+    install -Dm644 "${srcdir}/squashfs-root/${_pkgname}.desktop"\
+            "${pkgdir}/usr/share/applications/${_pkgname}.desktop"
+
+    # Icon images
+    install -dm755 "${pkgdir}/usr/share/"
+    cp -a "${srcdir}/squashfs-root/usr/share/icons" "${pkgdir}/usr/share/"
+
+    # Symlink executable
+    install -dm755 "${pkgdir}/usr/bin"
+    ln -s "/opt/${pkgname}/${pkgname}.AppImage" "${pkgdir}/usr/bin/${_pkgname}"
+
+    # Symlink license
+    # install -dm755 "${pkgdir}/usr/share/licenses/${pkgname}/"
+    # ln -s "/opt/$pkgname/LICENSE" "$pkgdir/usr/share/licenses/$pkgname"
+}