auto - see github.com/nicman23/mate_arch

2 files changed, 105 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..60e2d71d9e2a
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,47 @@
+pkgbase = atril-dev
+	pkgdesc = MATE document viewer
+	pkgver = 1.15.3
+	pkgrel = 1
+	url = http://mate-desktop.org
+	arch = i686
+	arch = x86_64
+	groups = mate-extra
+	license = GPL
+	makedepends = caja-dev
+	makedepends = djvulibre
+	makedepends = gtk-doc>=1.13
+	makedepends = intltool>=0.50.1
+	makedepends = gobject-introspection
+	makedepends = libgxps
+	makedepends = texlive-bin
+	makedepends = yelp-tools
+	makedepends = webkit2gtk
+	depends = dconf
+	depends = dbus
+	depends = desktop-file-utils
+	depends = glib2
+	depends = gtk3
+	depends = gtk-update-icon-cache
+	depends = libsecret
+	depends = libsm
+	depends = libspectre
+	depends = mate-desktop-dev
+	depends = mathjax
+	depends = poppler-glib
+	depends = webkitgtk
+	depends = zlib
+	optdepends = caja: Document Properties extension
+	optdepends = djvulibre: DjVu support
+	optdepends = libgxps: XPS support
+	optdepends = texlive-bin: DVI support
+	optdepends = yelp: for reading MATE help documents
+	provides = atril
+	provides = atril-gtk3
+	conflicts = atril
+	conflicts = atril-gtk3
+	source = http://pub.mate-desktop.org/releases/1.15/atril-1.15.3.tar.xz
+	sha1sums = d13011111732e7db6196702e66183c19dd1828b4
+
+pkgname = atril-dev
+	pkgdesc = MATE document viewer (GTK3 version)
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..ffeb62a692b4
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,58 @@
+# Maintainer:   Νικόλαος Κυριάκος Φυτίλης <n-fit@live.com>
+# Contributor:  eadrom <eadrom@archlinux.info>
+# Contributor:  Martin Wimpress <code@flexion.org>
+
+_ver=1.15
+_pkgbase=atril
+pkgname="${_pkgbase}-dev"
+pkgver=${_ver}.3
+pkgrel=1
+pkgdesc="MATE document viewer"
+url="http://mate-desktop.org"
+arch=('i686' 'x86_64')
+provides=("${_pkgbase}" "${_pkgbase}-gtk3")
+conflicts=("${_pkgbase}" "${_pkgbase}-gtk3")
+license=('GPL')
+depends=('dconf' 'dbus' 'desktop-file-utils' 'glib2' 'gtk3' 'gtk-update-icon-cache' 
+         'libsecret' 'libsm' 'libspectre' 'mate-desktop-dev' 'mathjax' 
+         'poppler-glib' 'webkitgtk' 'zlib')
+makedepends=('caja-dev' 'djvulibre' 'gtk-doc>=1.13' 'intltool>=0.50.1' 'gobject-introspection' 'libgxps'
+             'texlive-bin' 'yelp-tools' 'webkit2gtk')
+optdepends=('caja: Document Properties extension'
+            'djvulibre: DjVu support'
+            'libgxps: XPS support'
+            'texlive-bin: DVI support'
+            'yelp: for reading MATE help documents')
+groups=('mate-extra')
+source=("http://pub.mate-desktop.org/releases/${_ver}/${_pkgbase}-${pkgver}.tar.xz")
+sha1sums=('d13011111732e7db6196702e66183c19dd1828b4')
+
+prepare() {
+    cd "${srcdir}"
+    mv "${_pkgbase}-${pkgver}" "${_pkgbase}-gtk3"
+}
+
+build() {
+    cd "${srcdir}/${_pkgbase}-gtk3"
+    ./configure \
+        --prefix=/usr \
+        --libexecdir=/usr/lib/${_pkgbase} \
+        --with-gtk=3.0 \
+        --enable-gtk-doc \
+        --enable-djvu \
+        --enable-dvi \
+        --enable-epub \
+        --enable-t1lib \
+        --enable-pixbuf \
+        --enable-comics \
+        --enable-xps \
+        --enable-introspection \
+        --disable-static
+    make
+}
+
+package() {
+    pkgdesc+=' (GTK3 version)'
+    cd "${srcdir}/${_pkgbase}-gtk3"
+    make DESTDIR="${pkgdir}" install
+}