Cleaned up and merged axoloti-git and axoloti-runtime-git PKGBUILDs and changed target to latest stable release

4 files changed, 146 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..121ca8de0baa
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,35 @@
+pkgbase = axoloti
+	pkgdesc = Firmware and GUI for the Axoloti Core
+	pkgver = 1.0.12
+	pkgrel = 1
+	url = http://www.axoloti.com
+	install = axoloti.install
+	arch = x86_64
+	license = GPL
+	makedepends = apache-ant
+	makedepends = unzip
+	depends = java-runtime=7
+	depends = bash
+	depends = gtk2
+	depends = udev
+	depends = lib32-bzip2
+	depends = lib32-zlib
+	depends = lib32-ncurses
+	conflicts = axoloti-git
+	conflicts = axoloti-runtime-git
+	options = !strip
+	source = git+https://github.com/axoloti/axoloti.git
+	source = axoloti.sh
+	source = http://sourceforge.net/projects/chibios/files/ChibiOS_RT%20stable/Version%202.6.9/ChibiOS_2.6.9.zip
+	source = https://launchpad.net/gcc-arm-embedded/4.9/4.9-2015-q2-update/+download/gcc-arm-none-eabi-4_9-2015q2-20150609-linux.tar.bz2
+	source = libusb-1.0.19.tar.bz2::http://sourceforge.net/projects/libusb/files/libusb-1.0/libusb-1.0.19/libusb-1.0.19.tar.bz2/download
+	source = http://dfu-util.sourceforge.net/releases/dfu-util-0.8.tar.gz
+	sha512sums = SKIP
+	sha512sums = d3df8647a7adb5df40549fe8f81579df11cbe409527f42101d5a1948102895afbd764ee0b7dfb53f56694aea4ba0b1ffeadee012d7b36a9c032d686e1586a0b3
+	sha512sums = 9724896d82cec1f0eb222bebb7b9b97173ec9b536d7f7bad36cebff24323a8c439db1693ba45107ac6087c9cc339da0b420392deea458ef2f383cd72e2916d9d
+	sha512sums = 73fbd6c2ba6350422b8b708456e2344d785344aa57777bcd7b5a4d9b8524eeed13d5b10eb47e1c13513519e1e670db726e7f969c4ca9124f33c9dfe04e6e7a8a
+	sha512sums = f42f0187bfec16ebabad64efef7a7651ee85dcf2af1b7cbe543b7de615f9c6432f7eea5fcc6b23335591dcad287c905eb9bd56199cc5d3b47435027ad678f2c1
+	sha512sums = a192019654a03f816c8270257785d504bd88ca279844d7d01082b1b1eb219a87135691ccb7cec5de951a87e0864fc39b55f1774c78b4c851940ba467412bee6e
+
+pkgname = axoloti
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..5155f66ea1f4
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,82 @@
+# Maintainer: gato_lento <vukk.euob at gmail>
+# Based on axoloti-git and axoloti-runtime-git PKGBUILDs by: Joakim Reinert <mail+aur@jreinert.com>
+
+pkgname=axoloti
+pkgver=1.0.12
+pkgrel=1
+pkgdesc='Firmware and GUI for the Axoloti Core'
+arch=('x86_64')
+url='http://www.axoloti.com'
+license=('GPL')
+depends=('java-runtime=7' 'bash' 'gtk2' 'udev' 'lib32-bzip2' 'lib32-zlib' 'lib32-ncurses')
+makedepends=('apache-ant' 'unzip')
+conflicts=('axoloti-git' 'axoloti-runtime-git')
+options=('!strip')
+install="$pkgname.install"
+
+_chibios_version=2.6.9
+_chibios=ChibiOS_${_chibios_version}
+_chibios_archive=${_chibios}.zip
+_toolchain=gcc-arm-none-eabi-4_9-2015q2
+_toolchain_archive=${_toolchain}-20150609-linux.tar.bz2
+_libusb=libusb-1.0.19
+_libusb_archive=${_libusb}.tar.bz2
+_dfu_util=dfu-util-0.8
+_dfu_util_archive=${_dfu_util}.tar.gz
+
+source=(
+  "git+https://github.com/axoloti/axoloti.git"
+  "axoloti.sh"
+  "http://sourceforge.net/projects/chibios/files/ChibiOS_RT%20stable/Version%20${_chibios_version}/${_chibios_archive}"
+  "https://launchpad.net/gcc-arm-embedded/4.9/4.9-2015-q2-update/+download/${_toolchain_archive}"
+  "${_libusb_archive}::http://sourceforge.net/projects/libusb/files/libusb-1.0/${_libusb}/${_libusb_archive}/download"
+  "http://dfu-util.sourceforge.net/releases/${_dfu_util_archive}"
+)
+
+sha512sums=(
+  SKIP
+  d3df8647a7adb5df40549fe8f81579df11cbe409527f42101d5a1948102895afbd764ee0b7dfb53f56694aea4ba0b1ffeadee012d7b36a9c032d686e1586a0b3
+  9724896d82cec1f0eb222bebb7b9b97173ec9b536d7f7bad36cebff24323a8c439db1693ba45107ac6087c9cc339da0b420392deea458ef2f383cd72e2916d9d
+  73fbd6c2ba6350422b8b708456e2344d785344aa57777bcd7b5a4d9b8524eeed13d5b10eb47e1c13513519e1e670db726e7f969c4ca9124f33c9dfe04e6e7a8a
+  f42f0187bfec16ebabad64efef7a7651ee85dcf2af1b7cbe543b7de615f9c6432f7eea5fcc6b23335591dcad287c905eb9bd56199cc5d3b47435027ad678f2c1
+  a192019654a03f816c8270257785d504bd88ca279844d7d01082b1b1eb219a87135691ccb7cec5de951a87e0864fc39b55f1774c78b4c851940ba467412bee6e
+)
+
+build() {
+    cd $pkgname
+    git checkout $pkgver
+    mkdir -p "$srcdir/${pkgname}-runtime/"{platform_linux/{bin,lib,src},chibios}
+    cp -r "$srcdir/$_chibios"/* "$srcdir/${pkgname}-runtime/chibios/"
+    unzip -q -o "$srcdir/${pkgname}-runtime/chibios/ext/fatfs-0.9-patched.zip" -d "$srcdir/${pkgname}-runtime/chibios/ext"
+    cp -r "$srcdir/$_toolchain"/* "$srcdir/${pkgname}-runtime/platform_linux/"
+    cd "$srcdir/$_libusb"
+    patch -N -p1 < "$srcdir/$pkgname/platform_linux/src/libusb.stdfu.patch"
+    ./configure --prefix="$srcdir/${pkgname}-runtime/platform_linux"
+    make
+    make install
+    cd "$srcdir/$_dfu_util"
+    ./configure --prefix="$srcdir/${pkgname}-runtime/platform_linux" \
+        USB_LIBS="$srcdir/${pkgname}-runtime/platform_linux/lib/libusb-1.0.a -ludev -pthread" \
+        USB_CFLAGS="-I$srcdir/${pkgname}-runtime/platform_linux/include/libusb-1.0/"
+    make
+    make install
+    make clean
+    ldd "$srcdir/${pkgname}-runtime/platform_linux/bin/dfu-util"
+    cd "$srcdir/$pkgname"
+    echo '##### building GUI... #####'
+    ant
+}
+
+package() {
+    mkdir -p "$pkgdir/opt/${pkgname}-runtime/platform_linux"
+    cp -r "$srcdir/${pkgname}-runtime/platform_linux/"{arm-none-eabi,bin,include,lib} "$pkgdir/opt/${pkgname}-runtime/platform_linux/"
+    cp -r "$srcdir/$pkgname/firmware" "$pkgdir/opt/${pkgname}-runtime/"
+    cp -r "$srcdir/${pkgname}-runtime/chibios" "$pkgdir/opt/${pkgname}-runtime/chibios/"
+    cp -r "$srcdir/$pkgname/CMSIS" "$pkgdir/opt/${pkgname}-runtime/CMSIS"
+    rm -rf "$pkgdir/opt/${pkgname}-runtime/platform_linux/arm-none-eabi/lib/"{armv6-m,armv7-ar,armv7-m}
+    rm -rf "$pkgdir/opt/${pkgname}-runtime/platform_linux/lib/gcc/arm-none-eabi/4.9.3/"{armv6-m,armv7-ar,armv7-m}
+    install -Dm755 "$srcdir/$pkgname/platform_linux/compile_firmware.sh" "$pkgdir/opt/${pkgname}-runtime/platform_linux/compile_firmware.sh"
+    install -Dm644 "$srcdir/$pkgname/platform_linux/49-axoloti.rules" "$pkgdir/usr/lib/udev/rules.d/49-axoloti.rules"
+    install -Dm644 "$srcdir/$pkgname/dist/Axoloti.jar" "$pkgdir/usr/share/$pkgname/Axoloti.jar"
+    install -Dm755 "$srcdir/axoloti.sh" "$pkgdir/usr/bin/axoloti"
+}
diff --git a/axoloti.install b/axoloti.install
new file mode 100644
index 000000000000..9c9bd0ef00a8
--- /dev/null
+++ b/axoloti.install
@@ -0,0 +1,21 @@
+compile_firmware() {
+    echo '##### compiling firmware... #####'
+    cd /opt/axoloti-runtime/platform_linux
+    BUILDDIR=/opt/axoloti-runtime/firmware/build ./compile_firmware.sh
+}
+
+remove_firmware() {
+    rm -rf /opt/axoloti-runtime/firmware
+}
+
+post_install() {
+    compile_firmware
+}
+
+post_upgrade() {
+    compile_firmware
+}
+
+pre_remove() {
+    remove_firmware
+}
diff --git a/axoloti.sh b/axoloti.sh
new file mode 100644
index 000000000000..a519106aba78
--- /dev/null
+++ b/axoloti.sh
@@ -0,0 +1,8 @@
+#!/usr/bin/bash
+
+export axoloti_release=/opt/axoloti-runtime
+export axoloti_runtime=/opt/axoloti-runtime
+export axoloti_firmware=/opt/axoloti-runtime/firmware
+export axoloti_home="${XDG_DATA_HOME:-"$HOME/.local/share/"}/axoloti"
+
+java -jar /usr/share/axoloti/Axoloti.jar "$@" 2>&1 | tee "$axoloti_home/axoloti.log"