Initial commit

2 files changed, 104 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..bc50f3513c85
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,44 @@
+# Generated by mksrcinfo v7
+# Thu Oct 15 03:30:58 UTC 2015
+pkgbase = backintime-git
+	pkgver = 1.1.8.r15.g45f54e6
+	pkgrel = 1
+	url = http://backintime.le-web.org
+	arch = any
+	license = GPL
+	makedepends = git
+	makedepends = python
+	source = backintime::git://github.com/bit-team/backintime.git
+	md5sums = SKIP
+
+pkgname = backintime-git
+	pkgdesc = Simple backup/snapshot system inspired by Flyback and TimeVault. QT4 GUI version.
+	depends = backintime-cli-git
+	depends = libnotify
+	depends = polkit
+	depends = python-dbus
+	depends = python-pyqt4
+	depends = xorg-xdpyinfo
+	optdepends = meld: diff tool
+	optdepends = kompare: diff tool
+	optdepends = python-secretstorage: store passwords
+	provides = backintime
+	conflicts = backintime
+	conflicts = backintime-gnome
+	conflicts = backintime-gtk
+	conflicts = backintime-kde4
+	conflicts = backintime-qt4
+
+pkgname = backintime-cli-git
+	pkgdesc = Simple backup/snapshot system inspired by Flyback and TimeVault. CLI version.
+	depends = rsync
+	depends = cron
+	depends = openssh
+	depends = python-dbus
+	depends = python-keyring
+	optdepends = encfs: encrypted filesystems
+	optdepends = pm-utils: power management status check
+	optdepends = sshfs: remote filesystems
+	provides = backintime-cli
+	conflicts = backintime-cli
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..29b1b6f71547
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,60 @@
+# Maintainer: willemw <willemw12@gmail.com>
+
+_pkgname=backintime
+pkgname=($_pkgname-git $_pkgname-cli-git)
+pkgver=1.1.8.r15.g45f54e6
+pkgrel=1
+url="http://backintime.le-web.org"
+license=('GPL')
+arch=('any')
+makedepends=('git' 'python')
+source=($_pkgname::git://github.com/bit-team/backintime.git)
+md5sums=('SKIP')
+# https://wiki.archlinux.org/index.php/Makepkg#Signature_checking
+#validpgpkeys=('3E70692EE3DB8BDDA5991C90615F366D944B4826') # Germar Reitze
+
+pkgver() {
+  cd $_pkgname
+  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+prepare() {
+  cd $_pkgname
+}
+
+build() {
+  cd "$srcdir/$_pkgname/common"
+  ./configure --python3 --no-fuse-group
+  make
+
+  cd "$srcdir/$_pkgname/qt4"
+  ./configure --python3
+  make
+}
+
+package_backintime-cli-git() {
+  pkgdesc="Simple backup/snapshot system inspired by Flyback and TimeVault. CLI version."
+  depends=('rsync' 'cron' 'openssh' 'python-dbus' 'python-keyring')
+  optdepends=('encfs: encrypted filesystems'
+              'pm-utils: power management status check'
+              'sshfs: remote filesystems')
+  provides=($_pkgname-cli)
+  conflicts=($_pkgname-cli)
+
+  cd $_pkgname/common
+  make DESTDIR="$pkgdir" install 
+}
+
+package_backintime-git() {
+  pkgdesc="Simple backup/snapshot system inspired by Flyback and TimeVault. QT4 GUI version."
+  #depends=('backintime-cli' 'libnotify' 'polkit' 'python-dbus' 'python-pyqt4' 'xorg-xdpyinfo')
+  depends=('backintime-cli-git' 'libnotify' 'polkit' 'python-dbus' 'python-pyqt4' 'xorg-xdpyinfo')
+  optdepends=('meld: diff tool' 'kompare: diff tool'
+              'python-secretstorage: store passwords')
+  provides=($_pkgname)
+  conflicts=($_pkgname $_pkgname-gnome $_pkgname-gtk $_pkgname-kde4 $_pkgname-qt4)
+
+  cd $_pkgname/qt4
+  make DESTDIR="$pkgdir" install 
+}
+