Initial package bbcli-git

2 files changed, 72 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..5f524ada8fff
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,20 @@
+pkgbase = bbcli-git
+	pkgdesc = inoffical Bitbucket.org command line tool
+	pkgver = r39.50a3d2f
+	pkgrel = 1
+	url = https://github.com/craftamap/bb
+	arch = x86_64
+	arch = i686
+	arch = armv6h
+	arch = armv7h
+	arch = aarch64
+	license = MIT
+	makedepends = go
+	makedepends = git
+	provides = bbcli
+	conflicts = bbcli
+	source = bbcli-git::git://github.com/craftamap/bb.git
+	sha256sums = SKIP
+
+pkgname = bbcli-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..3227d5a86651
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,52 @@
+# Maintainer: Christian Muehlhaeuser <muesli at gmail dot com>
+
+pkgname=bbcli-git
+pkgver=r39.50a3d2f
+pkgrel=1
+pkgdesc="inoffical Bitbucket.org command line tool"
+arch=('x86_64' 'i686' 'armv6h' 'armv7h' 'aarch64')
+url="https://github.com/craftamap/bb"
+license=('MIT')
+makedepends=('go' 'git')
+provides=("${pkgname%-git}")
+conflicts=("${pkgname%-git}")
+source=($pkgname::git://github.com/craftamap/bb.git)
+sha256sums=('SKIP')
+
+prepare() {
+    export GOPATH="$srcdir/gopath"
+    export GO111MODULE=on
+
+    go clean -modcache
+}
+
+pkgver() {
+    cd "$srcdir/$pkgname"
+    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+build() {
+    cd "$srcdir/$pkgname"
+
+    export CGO_CPPFLAGS="${CPPFLAGS}"
+    export CGO_CFLAGS="${CFLAGS}"
+    export CGO_CXXFLAGS="${CXXFLAGS}"
+    export CGO_LDFLAGS="${LDFLAGS}"
+
+    go build \
+        -trimpath \
+        -buildmode=pie \
+        -mod=readonly \
+        -modcacherw \
+        -ldflags "-X main.Version=$pkgver -linkmode external -extldflags \"${LDFLAGS}\"" \
+        -o "${pkgname%-git}" .
+
+    go clean -modcache
+}
+
+package() {
+    cd "$srcdir/$pkgname"
+
+    install -Dm755 "${pkgname%-git}" "$pkgdir/usr/bin/${pkgname%-git}"
+    install -Dm644 "LICENSE" "$pkgdir/usr/share/licenses/${pkgname%-git}/LICENSE"
+}