1.9.0.rc1.r33.g302c8b53

2 files changed, 60 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..5470e9a0d864
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,20 @@
+pkgbase = black-magic-debug-git
+	pkgdesc = Plug&Play in application debugger for microcontrollers
+	pkgver = 1.9.0.rc1.r33.g302c8b53
+	pkgrel = 1
+	url = https://black-magic.org
+	arch = any
+	license = GPL
+	makedepends = git
+	makedepends = hidapi
+	makedepends = python
+	options = !strip
+	source = git+https://github.com/blackmagic-debug/blackmagic.git
+	sha256sums = SKIP
+
+pkgname = black-magic-debug-app-git
+	depends = libusb
+	depends = libftdi
+	depends = libhidapi-libusb.so
+
+pkgname = black-magic-debug-udev-git
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..52fe123e11a2
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,40 @@
+# Maintainer: Rafael Silva <perigoso@riseup.net>
+
+pkgbase='black-magic-debug-git'
+pkgname=(black-magic-debug-app-git black-magic-debug-udev-git)
+pkgver=1.9.0.rc1.r33.g302c8b53
+pkgrel=1
+pkgdesc='Plug&Play in application debugger for microcontrollers'
+arch=('any')
+url='https://black-magic.org'
+license=('GPL')
+makedepends=('git' 'hidapi' 'python')
+options=(!strip)
+source=("git+https://github.com/blackmagic-debug/blackmagic.git")
+sha256sums=('SKIP')
+
+pkgver() {
+    cd "blackmagic"
+
+    git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+    cd "blackmagic"
+
+    make PROBE_HOST=hosted ENABLE_RTT=1
+}
+
+package_black-magic-debug-udev-git() {
+    cd "blackmagic"
+
+    install -Dm 644 driver/99-blackmagic-uucp.rules "${pkgdir}"/usr/lib/udev/rules.d/99-blackmagic-uucp.rules
+}
+
+package_black-magic-debug-app-git() {
+    cd "blackmagic"
+
+    depends=('libusb' 'libftdi' 'libhidapi-libusb.so')
+
+    install -Dm 755 src/blackmagic "${pkgdir}"/usr/bin/blackmagic
+}