Initial upload: bookmark-git 0.1.0.r0.gf46e536-1

2 files changed, 54 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..b080e6004ed6
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,17 @@
+pkgbase = bookmark-git
+	pkgdesc = Save URLs from the terminal and open them quickly in the browser (git)
+	pkgver = 0.1.0.r0.gf46e536
+	pkgrel = 1
+	url = https://github.com/Szymongib/bookmark
+	arch = x86_64
+	license = MIT
+	makedepends = cargo
+	makedepends = git
+	provides = bookmark
+	conflicts = bookmark
+	conflicts = bookmark-bin
+	source = git+https://github.com/Szymongib/bookmark
+	sha512sums = SKIP
+
+pkgname = bookmark-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..dbe5463d95e5
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,37 @@
+# Maintainer: orhun <orhunparmaksiz@gmail.com>
+# https://github.com/orhun/pkgbuilds
+
+pkgname=bookmark-git
+pkgver=0.1.0.r0.gf46e536
+pkgrel=1
+pkgdesc="Save URLs from the terminal and open them quickly in the browser (git)"
+arch=('x86_64')
+url="https://github.com/Szymongib/bookmark"
+license=('MIT')
+makedepends=('cargo' 'git')
+conflicts=("${pkgname%-git}" "${pkgname%-git}-bin")
+provides=("${pkgname%-git}")
+source=("git+${url}")
+sha512sums=('SKIP')
+
+pkgver() {
+  cd "${pkgname%-git}"
+  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+  cd "${pkgname%-git}"
+  cargo build --release --locked --all-features
+}
+
+check() {
+  cd "${pkgname%-git}"
+  cargo test --release --locked
+}
+
+package() {
+  cd "${pkgname%-git}"
+  install -Dm 755 "target/release/${pkgname%-git}" -t "${pkgdir}/usr/bin"
+  install -Dm 644 README.md -t "$pkgdir/usr/share/doc/${pkgname%-git}"
+  install -Dm 644 LICENSE -t "$pkgdir/usr/share/licenses/${pkgname%-git}"
+}