init

3 files changed, 73 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..de3082e4de48
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,19 @@
+pkgbase = botim-appimage
+	pkgdesc = BOTIM - Free, Secure & Reliable Messages and Calls
+	pkgver = 1.6.3
+	pkgrel = 0
+	url = https://botim.me
+	arch = x86_64
+	license = custom:Commercial
+	depends = zlib
+	depends = hicolor-icon-theme
+	depends = fuse2
+	provides = botim
+	conflicts = botim
+	conflicts = botim-bin
+	noextract = botim-appimage-1.6.3.AppImage
+	options = !strip
+	source_x86_64 = botim-appimage-1.6.3.AppImage::https://cdn-web-sg.botim.me/downloads/desktop/linux/1.6.3/BOTIM-1.6.3.AppImage
+	sha256sums_x86_64 = 67bfa32f390559b6b9ab41a009eab3e57a9e537b5f5b87de71a03c64beccb4f2
+
+pkgname = botim-appimage
diff --git a/.gitignore b/.gitignore
new file mode 100644
index 000000000000..1eca835fa363
--- /dev/null
+++ b/.gitignore
@@ -0,0 +1,4 @@
+/pkg
+/src
+/*.AppImage
+*.pkg.*
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..e56799ace59f
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,50 @@
+# Maintainer: Light Ning <aur at i01 dot io>
+# Based  on the template from https://daveparrish.net/posts/2019-11-16-Better-AppImage-PKGBUILD-template.html
+
+_pkgname=botim
+
+pkgname="${_pkgname}"-appimage
+pkgver=1.6.3
+pkgrel=0
+pkgdesc="BOTIM - Free, Secure & Reliable Messages and Calls"
+arch=('x86_64')
+url="https://botim.me"
+license=('custom:Commercial')
+depends=('zlib' 'hicolor-icon-theme' 'fuse2')
+provides=("${_pkgname}")
+conflicts=("${_pkgname}" 'botim-bin')
+options=(!strip)
+_appimage="${pkgname}-${pkgver}.AppImage"
+source_x86_64=("${_appimage}::https://cdn-web-sg.botim.me/downloads/desktop/linux/${pkgver}/BOTIM-${pkgver}.AppImage")
+noextract=("${_appimage}")
+sha256sums_x86_64=('67bfa32f390559b6b9ab41a009eab3e57a9e537b5f5b87de71a03c64beccb4f2')
+
+prepare() {
+    chmod +x "${_appimage}"
+    ./"${_appimage}" --appimage-extract
+}
+
+build() {
+    # Adjust .desktop so it will work outside of AppImage container
+    sed -i -E "s|Exec=AppRun|Exec=env DESKTOPINTEGRATION=false /usr/bin/${_pkgname} %u|"\
+        "squashfs-root/${_pkgname}.desktop"
+    # Fix permissions; .AppImage permissions are 700 for all directories
+    chmod -R a-x+rX squashfs-root/usr
+}
+
+package() {
+    # AppImage
+    install -Dm755 "${srcdir}/${_appimage}" "${pkgdir}/opt/${pkgname}/${pkgname}.AppImage"
+
+    # Desktop file
+    install -Dm644 "${srcdir}/squashfs-root/${_pkgname}.desktop"\
+            "${pkgdir}/usr/share/applications/${_pkgname}.desktop"
+
+    # Icon images
+    install -dm755 "${pkgdir}/usr/share/"
+    cp -a "${srcdir}/squashfs-root/usr/share/icons" "${pkgdir}/usr/share/"
+
+    # Symlink executable
+    install -dm755 "${pkgdir}/usr/bin"
+    ln -s "/opt/${pkgname}/${pkgname}.AppImage" "${pkgdir}/usr/bin/${_pkgname}"
+}