new package

2 files changed, 82 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..059173cb0c27
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,36 @@
+pkgbase = buildbot-git
+	pkgver = 1.2.0.r40.g16dff07ce
+	pkgrel = 1
+	url = https://buildbot.net
+	arch = any
+	license = GPL
+	makedepends = git
+	makedepends = python-twisted
+	makedepends = python-jinja
+	makedepends = python-zope-interface
+	makedepends = python-future
+	makedepends = python-sqlalchemy-migrate
+	makedepends = python-dateutil
+	makedepends = python-txaio
+	makedepends = python-autobahn
+	makedepends = python-pyjwt
+	source = git+https://github.com/buildbot/buildbot.git
+	sha256sums = SKIP
+
+pkgname = buildbot-git
+	pkgdesc = The Continuous Integration Framework
+	depends = python-twisted
+	depends = python-jinja
+	depends = python-zope-interface
+	depends = python-future
+	depends = python-sqlalchemy-migrate
+	depends = python-dateutil
+	depends = python-txaio
+	depends = python-autobahn
+	depends = python-pyjwt
+
+pkgname = buildbot-worker-git
+	pkgdesc = Buildbot Worker Daemon
+	depends = python-twisted
+	depends = python-future
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..41a76b4f8f93
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,46 @@
+# Maintainer: Chih-Hsuan Yen <yan12125@gmail.com>
+# Forked from aur/buildbot. Original contributors:
+# Contributor: xRemaLx <anton.komolov@gmail.com>
+# Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
+# Contributor: William Rea <sillywilly@gmail.com>
+
+pkgbase=buildbot-git
+pkgname=('buildbot-git' 'buildbot-worker-git')
+pkgver=1.2.0.r40.g16dff07ce
+pkgrel=1
+arch=('any')
+url="https://buildbot.net"
+license=("GPL")
+makedepends=('git'
+             'python-twisted' 'python-jinja' 'python-zope-interface' 'python-future'
+             'python-sqlalchemy-migrate' 'python-dateutil' 'python-txaio'
+             'python-autobahn' 'python-pyjwt')
+source=(git+https://github.com/buildbot/buildbot.git)
+sha256sums=('SKIP')
+
+pkgver() {
+  cd buildbot
+  ( set -o pipefail
+    git describe --long --tag 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/^v//' ||
+    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+  )
+}
+
+
+package_buildbot-git() {
+  depends=('python-twisted' 'python-jinja' 'python-zope-interface' 'python-future'
+           'python-sqlalchemy-migrate' 'python-dateutil' 'python-txaio'
+           'python-autobahn' 'python-pyjwt')
+  pkgdesc="The Continuous Integration Framework"
+
+  cd buildbot/master
+  python setup.py install --root="$pkgdir" --optimize=1
+}
+
+package_buildbot-worker-git() {
+  pkgdesc="Buildbot Worker Daemon"
+  depends=('python-twisted' 'python-future')
+
+  cd buildbot/worker
+  python setup.py install --root="$pkgdir" --optimize=1
+}