Initial import

3 files changed, 223 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..3ef4322683b4
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,59 @@
+pkgbase = cairo-dock-plug-ins-git
+	pkgdesc = Plugins for Cairo-Dock
+	pkgver = 3.4.1.r7.88ae103
+	pkgrel = 1
+	url = http://glx-dock.org
+	arch = i686
+	arch = x86_64
+	license = GPL
+	makedepends = alsa-lib
+	makedepends = cmake
+	makedepends = dbus-sharp-glib
+	makedepends = fftw
+	makedepends = gnome-menus
+	makedepends = gtk-sharp-3
+	makedepends = gvfs
+	makedepends = libetpan
+	makedepends = libexif
+	makedepends = libical
+	makedepends = libpulse
+	makedepends = libxklavier
+	makedepends = lm_sensors
+	makedepends = python
+	makedepends = python2
+	makedepends = ruby
+	makedepends = upower
+	makedepends = vala
+	makedepends = vte3
+	makedepends = webkitgtk
+	makedepends = zeitgeist
+	depends = cairo-dock
+	optdepends = alsa-lib: Sound Control, Sound Effects applets
+	optdepends = dbus-sharp-glib: Mono API
+	optdepends = fftw: Impulse applet
+	optdepends = gnome-menus: Applications Menu applet
+	optdepends = gtk-sharp-3: Mono API
+	optdepends = gvfs: GVFS integration
+	optdepends = libetpan: Mail applet
+	optdepends = libexif: Slider applet
+	optdepends = libical: Clock applet
+	optdepends = libpulse: Impulse applet
+	optdepends = libxklavier: Keyboard Indicator applet
+	optdepends = lm_sensors: System Monitor applet
+	optdepends = python: Python 3 API
+	optdepends = python2: Python 2 API
+	optdepends = ruby: Ruby API
+	optdepends = upower: Power Manager applet
+	optdepends = vte3: Terminal applet
+	optdepends = webkitgtk: Weblets applet
+	optdepends = zeitgeist: Recent Events applet
+	provides = cairo-dock-plug-ins
+	conflicts = cairo-dock-plug-ins
+	replaces = cairo-dock-plugins-git
+	source = git+https://github.com/Cairo-Dock/cairo-dock-plug-ins.git
+	source = cairo-dock-plug-ins-mono.patch
+	sha256sums = SKIP
+	sha256sums = 91a32a93e27f4600c5aee0b6e7b4c7d8cc6711a40ac5d185021e616cf5d1bdb7
+
+pkgname = cairo-dock-plug-ins-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..6a3f798fc0ac
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,79 @@
+# Maintainer: Maxime Gauduin <alucryd@archlinux.org>
+# Contributor: Tofe <chris.chapuis@gmail.com>
+# Contributor: zhuqin <zhuqin83@gmail.com>
+# Contributor: tri1976 <trile7@gmail.com>
+# Contributor: snoopy33 <snoopy33@no-log.org>
+
+pkgname=cairo-dock-plug-ins-git
+pkgver=3.4.1.r7.88ae103
+pkgrel=1
+pkgdesc='Plugins for Cairo-Dock'
+arch=('i686' 'x86_64')
+url='http://glx-dock.org'
+license=('GPL')
+depends=('cairo-dock')
+makedepends=('alsa-lib' 'cmake' 'dbus-sharp-glib' 'fftw' 'gnome-menus'
+             'gtk-sharp-3' 'gvfs' 'libetpan' 'libexif' 'libical' 'libpulse'
+             'libxklavier' 'lm_sensors' 'python' 'python2' 'ruby' 'upower'
+             'vala' 'vte3' 'webkitgtk' 'zeitgeist')
+optdepends=('alsa-lib: Sound Control, Sound Effects applets'
+            'dbus-sharp-glib: Mono API'
+            'fftw: Impulse applet'
+            'gnome-menus: Applications Menu applet'
+            'gtk-sharp-3: Mono API'
+            'gvfs: GVFS integration'
+            'libetpan: Mail applet'
+            'libexif: Slider applet'
+            'libical: Clock applet'
+            'libpulse: Impulse applet'
+            'libxklavier: Keyboard Indicator applet'
+            'lm_sensors: System Monitor applet'
+            'python: Python 3 API'
+            'python2: Python 2 API'
+            'ruby: Ruby API'
+            'upower: Power Manager applet'
+            'vte3: Terminal applet'
+            'webkitgtk: Weblets applet'
+            'zeitgeist: Recent Events applet')
+replaces=('cairo-dock-plugins-git')
+provides=('cairo-dock-plug-ins')
+conflicts=('cairo-dock-plug-ins')
+source=('git+https://github.com/Cairo-Dock/cairo-dock-plug-ins.git'
+        'cairo-dock-plug-ins-mono.patch')
+sha256sums=('SKIP'
+            '91a32a93e27f4600c5aee0b6e7b4c7d8cc6711a40ac5d185021e616cf5d1bdb7')
+
+pkgver() {
+  cd cairo-dock-plug-ins
+
+  _tag='3.4.1'
+  echo "${_tag}.r$(git rev-list --count ${_tag}..HEAD).$(git rev-parse --short HEAD)"
+}
+
+prepare() {
+  cd cairo-dock-plug-ins
+
+  patch -Np1 -i ../cairo-dock-plug-ins-mono.patch
+}
+
+build() {
+  cd cairo-dock-plug-ins
+
+  if [[ -d build ]]; then
+    rm -rf build
+  fi
+  mkdir build && cd build
+
+  cmake .. \
+    -DCMAKE_BUILD_TYPE='Release' \
+    -DCMAKE_INSTALL_PREFIX='/usr'
+  make
+}
+
+package() {
+  cd cairo-dock-plug-ins/build
+
+  make DESTDIR="${pkgdir}" install
+}
+
+# vim: ts=2 sw=2 et:
diff --git a/cairo-dock-plug-ins-mono.patch b/cairo-dock-plug-ins-mono.patch
new file mode 100644
index 000000000000..cf4c3e682a65
--- /dev/null
+++ b/cairo-dock-plug-ins-mono.patch
@@ -0,0 +1,85 @@
+From cd956a7023bfc0d123394afd04469710d53f358e Mon Sep 17 00:00:00 2001
+From: Maxime Gauduin <alucryd@gmail.com>
+Date: Fri, 13 Mar 2015 14:46:03 +0100
+Subject: [PATCH] Use GTK3 Mono bindings
+
+---
+ CMakeLists.txt                      | 20 +++++++++++++++-----
+ Dbus/interfaces/mono/CDApplet.cs    |  2 +-
+ Dbus/interfaces/mono/CMakeLists.txt | 19 +++++++++++++------
+ 3 files changed, 29 insertions(+), 12 deletions(-)
+
+diff --git a/CMakeLists.txt b/CMakeLists.txt
+index 7b835ef..4be60eb 100644
+--- a/CMakeLists.txt
++++ b/CMakeLists.txt
+@@ -573,12 +573,22 @@ if (enable-mono-interface)
+ 	if (NOT GMCS_EXECUTABLE OR NOT EXISTS ${GMCS_EXECUTABLE})
+ 		message (STATUS "Could not find Mono compiler gmcs, won't build Mono interface.")
+ 	else()
+-		pkg_check_modules (MONO_PACKAGE dbus-sharp-2.0 dbus-sharp-glib-2.0 glib-sharp-2.0)
++		pkg_check_modules (MONO_PACKAGE dbus-sharp-2.0 dbus-sharp-glib-2.0)
++		pkg_search_module (GLIB_SHARP glib-sharp-3.0 glib-sharp-2.0)
+ 		if (NOT MONO_PACKAGE_FOUND)
+-			message (STATUS "Could not find dbus-sharp-2.0, dbus-sharp-glib-2.0 or glib-sharp-2.0; won't be built Mono interface.")
+-			message (WARNING "These modules are required to compile DBus applet with Mono interface: dbus-sharp-2.0, dbus-sharp-glib-2.0 and glib-sharp-2.0")
+-			set (MODULES_MISSING "${MODULES_MISSING} dbus-sharp-2.0 dbus-sharp-glib-2.0 glib-sharp-2.0")
+-		else()
++			message (STATUS "Could not find dbus-sharp-2.0 and dbus-sharp-glib-2.0; won't build Mono interface.")
++			message (WARNING "These modules are required to compile DBus applet with Mono interface: dbus-sharp-2.0 and dbus-sharp-glib-2.0")
++			set (MODULES_MISSING "${MODULES_MISSING} dbus-sharp-2.0 dbus-sharp-glib-2.0")
++		endif()
++		if (NOT GLIB_SHARP_FOUND)
++			message (STATUS "Could not find either glib-sharp-3.0 or glib-sharp-2.0; won't build Mono interface.")
++			message (WARNING "One of these modules is required to compile DBus applet with Mono interface: glib-sharp-3.0 or glib-sharp-2.0")
++			set (MODULES_MISSING "${MODULES_MISSING} glib-sharp-3.0")
++		endif()
++		if (MONO_PACKAGE_FOUND AND GLIB_SHARP_FOUND)
++			if (GLIB_SHARP_VERSION VERSION_GREATER 2.99.0)
++				set (GLIB_SHARP_3 TRUE)
++			endif()
+ 			set (MONO_FOUND TRUE)
+ 			set (with_mono yes)
+ 		endif()
+diff --git a/Dbus/interfaces/mono/CDApplet.cs b/Dbus/interfaces/mono/CDApplet.cs
+index 2ced75a..3b047be 100644
+--- a/Dbus/interfaces/mono/CDApplet.cs
++++ b/Dbus/interfaces/mono/CDApplet.cs
+@@ -21,7 +21,7 @@
+ // Make your own class derive from a CDApplet, and override the functions you need (the ones which don't start with an underscore).
+ 
+ // Compile it with the following command, then rename 'demo_mono.exe' to 'demo_mono'.
+-// gmcs /target:library CDApplet.cs ISubApplet.cs IApplet.cs -pkg:dbus-sharp-2.0 -pkg:dbus-sharp-glib-2.0 -pkg:glib-sharp-2.0
++// gmcs /target:library CDApplet.cs ISubApplet.cs IApplet.cs -pkg:dbus-sharp-2.0 -pkg:dbus-sharp-glib-2.0 -pkg:glib-sharp-3.0
+   //////////////////////////
+  ////// dependancies //////
+ //////////////////////////
+diff --git a/Dbus/interfaces/mono/CMakeLists.txt b/Dbus/interfaces/mono/CMakeLists.txt
+index d7a27a2..eba8069 100644
+--- a/Dbus/interfaces/mono/CMakeLists.txt
++++ b/Dbus/interfaces/mono/CMakeLists.txt
+@@ -1,11 +1,18 @@
+ 	
+ ########### install files ###############
+-
+-execute_process(COMMAND ${GMCS_EXECUTABLE}
+-	-target:library
+-	-pkg:dbus-sharp-2.0 -pkg:dbus-sharp-glib-2.0 -pkg:glib-sharp-2.0
+-	-out:${CMAKE_CURRENT_BINARY_DIR}/CDApplet.dll
+-	${CMAKE_CURRENT_SOURCE_DIR}/CDApplet.cs ${CMAKE_CURRENT_SOURCE_DIR}/ISubApplet.cs ${CMAKE_CURRENT_SOURCE_DIR}/IApplet.cs)
++if (GLIB_SHARP_3)
++	execute_process(COMMAND ${GMCS_EXECUTABLE}
++		-target:library
++		-pkg:dbus-sharp-2.0 -pkg:dbus-sharp-glib-2.0 -pkg:glib-sharp-3.0
++		-out:${CMAKE_CURRENT_BINARY_DIR}/CDApplet.dll
++		${CMAKE_CURRENT_SOURCE_DIR}/CDApplet.cs ${CMAKE_CURRENT_SOURCE_DIR}/ISubApplet.cs ${CMAKE_CURRENT_SOURCE_DIR}/IApplet.cs)
++else()
++	execute_process(COMMAND ${GMCS_EXECUTABLE}
++		-target:library
++		-pkg:dbus-sharp-2.0 -pkg:dbus-sharp-glib-2.0 -pkg:glib-sharp-2.0
++		-out:${CMAKE_CURRENT_BINARY_DIR}/CDApplet.dll
++		${CMAKE_CURRENT_SOURCE_DIR}/CDApplet.cs ${CMAKE_CURRENT_SOURCE_DIR}/ISubApplet.cs ${CMAKE_CURRENT_SOURCE_DIR}/IApplet.cs)
++endif()
+ ### find how to register to GAC ...
+ set (MONO_LIB_DIR "${CMAKE_INSTALL_PREFIX}/lib/cli/cairo-dock-plug-ins")
+ install (FILES ${CMAKE_CURRENT_BINARY_DIR}/CDApplet.dll