auto - see github.com/nicman23/mate_arch

2 files changed, 84 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..81eebc9b19e1
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,36 @@
+pkgbase = caja-dev
+	pkgdesc = File manager for the MATE desktop
+	pkgver = 1.15.3
+	pkgrel = 1
+	url = http://mate-desktop.org
+	arch = i686
+	arch = x86_64
+	groups = mate
+	license = GPL
+	makedepends = gobject-introspection
+	makedepends = mate-common
+	depends = dbus
+	depends = desktop-file-utils
+	depends = exempi
+	depends = glib2
+	depends = gtk3
+	depends = gtk-update-icon-cache
+	depends = gvfs
+	depends = libexif
+	depends = libunique3
+	depends = libxt
+	depends = mate-desktop-dev
+	depends = shared-mime-info
+	depends = startup-notification
+	optdepends = gstreamer: automatic media playback when mouseover
+	optdepends = gvfs-smb: To connect to Samba/Windows shares
+	provides = caja
+	provides = caja-gtk3
+	conflicts = caja
+	conflicts = caja-gtk3
+	source = http://pub.mate-desktop.org/releases/1.15/caja-1.15.3.tar.xz
+	sha1sums = df54b9862433583a4ddeaf5213aa448b4dee994d
+
+pkgname = caja-dev
+	pkgdesc = File manager for the MATE desktop (GTK3 version)
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..30d00b269b44
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,48 @@
+# Maintainer:   Νικόλαος Κυριάκος Φυτίλης <n-fit@live.com>
+# Contributor:  eadrom <eadrom@archlinux.info>
+# Contributor:  Martin Wimpress <code@flexion.org>
+
+_ver=1.15
+_pkgbase=caja
+pkgname="${_pkgbase}-dev"
+pkgver=${_ver}.3
+pkgrel=1
+pkgdesc="File manager for the MATE desktop"
+url="http://mate-desktop.org"
+arch=('i686' 'x86_64')
+provides=("${_pkgbase}" "${_pkgbase}-gtk3")
+conflicts=("${_pkgbase}" "${_pkgbase}-gtk3")
+license=('GPL')
+depends=('dbus' 'desktop-file-utils' 'exempi' 'glib2' 'gtk3' 'gtk-update-icon-cache'
+         'gvfs' 'libexif' 'libunique3' 'libxt' 'mate-desktop-dev' 'shared-mime-info'
+         'startup-notification')
+makedepends=('gobject-introspection' 'mate-common')
+optdepends=('gstreamer: automatic media playback when mouseover'
+            'gvfs-smb: To connect to Samba/Windows shares')
+groups=('mate')
+source=("http://pub.mate-desktop.org/releases/${_ver}/${_pkgbase}-${pkgver}.tar.xz")
+sha1sums=('df54b9862433583a4ddeaf5213aa448b4dee994d')
+
+prepare() {
+    cd "${srcdir}"
+    mv "${_pkgbase}-${pkgver}" "${_pkgbase}-gtk3"
+}
+
+build() {
+    cd "${srcdir}/${_pkgbase}-gtk3"
+    ./configure \
+        --prefix=/usr \
+        --libexecdir=/usr/lib/${_pkgbase} \
+        --with-gtk=3.0 \
+        --enable-unique \
+        --enable-introspection \
+        --disable-static \
+        --disable-update-mimedb
+    make
+}
+
+package() {
+    pkgdesc+=' (GTK3 version)'
+    cd "${srcdir}/${_pkgbase}-gtk3"
+    make DESTDIR="${pkgdir}" install
+}