Initial commit

4 files changed, 76 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..94036d2f9ff6
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,20 @@
+pkgbase = celeste64-fuji-beta
+	pkgdesc = A free and open source mod loader for Celeste 64: Fragments of the Mountain (beta branch)
+	pkgver = 0.5.0.r0.8c1d346
+	pkgrel = 1
+	url = https://fujiapi.github.io
+	arch = x86_64
+	arch = aarch64
+	license = custom:celeste64-fuji
+	makedepends = git
+	makedepends = dotnet-sdk
+	provides = celeste64-fuji
+	conflicts = celeste64-fuji
+	options = !strip
+	options = !debug
+	source = celeste64-fuji::git+https://github.com/FujiAPI/Fuji#branch=beta
+	source = fuji.desktop
+	sha256sums = SKIP
+	sha256sums = 35ffe246db00f9a6e54d50eb7e37d637ac2107413e88f2fe12d27c64ef1830dd
+
+pkgname = celeste64-fuji-beta
diff --git a/.gitignore b/.gitignore
new file mode 100644
index 000000000000..ef43099aa59a
--- /dev/null
+++ b/.gitignore
@@ -0,0 +1,5 @@
+src/
+pkg/
+*.pkg.*
+
+celeste64-fuji/
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..e9370a448cba
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,41 @@
+# Maintainer: Noa <coolreader18@gmail.com>
+pkgname=celeste64-fuji-beta
+pkgver=0.5.0.r0.8c1d346
+pkgrel=1
+pkgdesc="A free and open source mod loader for Celeste 64: Fragments of the Mountain (beta branch)"
+arch=(x86_64 aarch64)
+url="https://fujiapi.github.io"
+license=('custom:celeste64-fuji')
+depends=()
+makedepends=('git' dotnet-sdk)
+options=('!strip' '!debug')
+provides=("${pkgname%-beta}")
+conflicts=("${pkgname%-beta}")
+source=('celeste64-fuji::git+https://github.com/FujiAPI/Fuji#branch=beta'
+				fuji.desktop)
+noextract=()
+sha256sums=('SKIP'
+            '35ffe246db00f9a6e54d50eb7e37d637ac2107413e88f2fe12d27c64ef1830dd')
+
+pkgver() {
+	cd "$srcdir/${pkgname%-beta}"
+	last_common=$(git merge-base main HEAD)
+	num_revs=$(git rev-list --count "$last_common"...HEAD)
+	ver=$(git cat-file blob "$last_common":Celeste64.Launcher/Celeste64.Launcher.csproj | grep '<Version>' | sed 's/\s*\|<\/\?Version>//g')
+	printf "%s.r%s.%s" "$ver" "$num_revs" "$(git rev-parse --short HEAD)"
+}
+
+build() {
+	cd "$srcdir/${pkgname%-beta}"
+	dotnet build Celeste64.Launcher/Celeste64.Launcher.csproj -c Release --ucr
+	awk '/License/{license=1} !$0{license=0} license' README.md >License.txt
+}
+
+package() {
+	cd "$srcdir/${pkgname%-beta}"
+	dotnet publish Celeste64.Launcher/Celeste64.Launcher.csproj -c Release --ucr --no-build -o "$pkgdir"/opt/fuji
+	cp -r Content Mods fuji.png "$pkgdir"/opt/fuji
+	install -Dm 644 "$srcdir"/fuji.desktop -t "$pkgdir"/usr/share/applications
+	install -Dm 644 License.txt -t "$pkgdir"/usr/share/licenses/fuji
+	install -Dm 644 Source/License.txt "$pkgdir"/usr/share/licenses/fuji/SourceLicense.txt
+}
diff --git a/fuji.desktop b/fuji.desktop
new file mode 100644
index 000000000000..da8d6e04cbf1
--- /dev/null
+++ b/fuji.desktop
@@ -0,0 +1,10 @@
+[Desktop Entry]
+Name=Fuji Mod Loader
+Comment=A free and open source mod loader for Celeste 64: Fragments of the Mountain
+Exec=/opt/fuji/Celeste64-Fuji
+Path=/opt/fuji
+Categories=Game;
+Type=Application
+Icon=/opt/fuji/fuji.png
+Terminal=false
+StartupNotify=false