Initial commit

2 files changed, 106 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..5feb9860a2b9
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,41 @@
+pkgbase = circos
+	pkgdesc = A software package for visualizing data in a circular layout
+	pkgver = 0.69_4
+	pkgrel = 1
+	url = http://circos.ca
+	arch = any
+	license = GPL
+	depends = perl-carp
+	depends = perl-clone
+	depends = perl-config-general
+	depends = perl-data-dumper
+	depends = perl-digest-md5
+	depends = perl-file-temp
+	depends = perl-font-ttf
+	depends = perl-gd
+	depends = perl-getopt-long
+	depends = perl-list-moreutils
+	depends = perl-math-bezier
+	depends = perl-math-round
+	depends = perl-math-complex
+	depends = perl-math-vecstat
+	depends = perl-memoize
+	depends = perl-params-validate
+	depends = perl-pod-usage
+	depends = perl-readonly
+	depends = perl-regexp-common
+	depends = perl-set-intspan
+	depends = perl-statistics-basic
+	depends = perl-storable
+	depends = perl-svg
+	depends = perl-text-balanced
+	depends = perl-text-format
+	depends = perl-time-hires
+	optdepends = circos-docs: tutorials
+	optdepends = circos-tools: addons
+	noextract = circos-0.69-4.tgz
+	source = http://circos.ca/distribution/circos-0.69-4.tgz
+	sha256sums = 26cde7700e797643d8edd647329be4ebdfe87691cb8e4b082078cd910f22ca92
+
+pkgname = circos
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..8023edbc4072
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,65 @@
+# Maintainer: archlinux.info:tdy
+
+pkgname=circos
+pkgver=0.69_4
+pkgrel=1
+pkgdesc="A software package for visualizing data in a circular layout"
+arch=(any)
+url=http://circos.ca
+license=(GPL)
+depends=(
+  perl-carp
+  perl-clone
+  perl-config-general
+  perl-data-dumper
+  perl-digest-md5
+  perl-file-temp
+  perl-font-ttf
+  perl-gd
+  perl-getopt-long
+  perl-list-moreutils
+  perl-math-bezier
+  perl-math-round
+  perl-math-complex
+  perl-math-vecstat
+  perl-memoize
+  perl-params-validate
+  perl-pod-usage
+  perl-readonly
+  perl-regexp-common
+  perl-set-intspan
+  perl-statistics-basic
+  perl-storable
+  perl-svg
+  perl-text-balanced
+  perl-text-format
+  perl-time-hires
+)
+optdepends=('circos-docs: tutorials'
+            'circos-tools: addons')
+source=(http://$pkgname.ca/distribution/$pkgname-${pkgver/_/-}.tgz)
+noextract=($pkgname-${pkgver/_/-}.tgz)
+sha256sums=(26cde7700e797643d8edd647329be4ebdfe87691cb8e4b082078cd910f22ca92)
+
+package() {
+  # dist
+  bsdtar -xf $pkgname-${pkgver/_/-}.tgz -C "$pkgdir" \
+    -s ":^$pkgname-${pkgver/_/-}:opt/$pkgname:" \
+    $pkgname-${pkgver/_/-}/{bin,data,error,etc,example,fonts,lib,tiles}
+
+  # docs
+  bsdtar -xf $pkgname-${pkgver/_/-}.tgz -C "$pkgdir" \
+    -s ":^$pkgname-${pkgver/_/-}:usr/share/doc/$pkgname:" \
+    $pkgname-${pkgver/_/-}/{README,CITATION}
+
+  # sanitize
+  rm -f "$pkgdir"/opt/$pkgname/bin/{$pkgname.exe,compile.{bat,make}}
+  find "$pkgdir" -exec sh -c \
+    "file '{}' | grep -qE 'ELF|executable|directory' && chmod 755 '{}' || chmod 644 '{}'" \;
+  chown -R root:root "$pkgdir"
+
+  # symlinks
+  install -m 755 -d "$pkgdir"/usr/bin/
+  ln -sf /opt/$pkgname/bin/$pkgname "$pkgdir"/usr/bin/
+  ln -sf /opt/$pkgname/bin/gddiag "$pkgdir"/usr/bin/
+}