Initial commit

2 files changed, 134 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..83d2393bf671
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,48 @@
+pkgbase = citra-ex-git
+	pkgdesc = An experimental open-source Nintendo 3DS emulator/debugger (single package)
+	pkgver = r6193.98438258c
+	pkgrel = 1
+	url = https://github.com/citra-emu/citra/
+	arch = i686
+	arch = x86_64
+	license = GPL2
+	makedepends = git
+	makedepends = cmake
+	makedepends = sdl2
+	makedepends = qt5-base
+	makedepends = shared-mime-info
+	makedepends = desktop-file-utils
+	depends = qt5-base
+	depends = sdl2
+	depends = shared-mime-info
+	depends = desktop-file-utils
+	provides = citra
+	conflicts = citra-git
+	conflicts = citra-qt-git
+	source = citra::git+https://github.com/citra-emu/citra
+	source = git+https://github.com/citra-emu/ext-boost
+	source = git+https://github.com/neobrain/nihstro
+	source = git+https://github.com/citra-emu/ext-soundtouch
+	source = git+https://github.com/philsquared/Catch
+	source = git+https://github.com/MerryMage/dynarmic
+	source = git+https://github.com/herumi/xbyak
+	source = git+https://github.com/weidai11/cryptopp
+	source = git+https://github.com/fmtlib/fmt
+	source = git+https://github.com/lsalzman/enet
+	source = git+https://github.com/whoshuu/cpr
+	source = git+https://github.com/benhoyt/inih
+	md5sums = SKIP
+	md5sums = SKIP
+	md5sums = SKIP
+	md5sums = SKIP
+	md5sums = SKIP
+	md5sums = SKIP
+	md5sums = SKIP
+	md5sums = SKIP
+	md5sums = SKIP
+	md5sums = SKIP
+	md5sums = SKIP
+	md5sums = SKIP
+
+pkgname = citra-ex-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..bd5a2bd87a8c
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,86 @@
+# Maintainer: Benjamin Hodgetts <ben@xnode.org>
+# Contributor: Emmanuel Gil Peyrot <linkmauve@linkmauve.fr>
+# Contributor: ceri
+
+_pkgbase='citra'
+pkgbase="citra-ex-git"
+pkgname="citra-ex-git"
+pkgver=r6193.98438258c
+pkgrel=1
+pkgdesc="An experimental open-source Nintendo 3DS emulator/debugger (single package)"
+arch=('i686' 'x86_64')
+url="https://github.com/citra-emu/citra/"
+license=('GPL2')
+provides=('citra')
+conflicts=('citra-git' 'citra-qt-git')
+depends=('qt5-base' 'sdl2' 'shared-mime-info' 'desktop-file-utils')
+makedepends=('git' 'cmake' 'sdl2' 'qt5-base' 'shared-mime-info' 'desktop-file-utils')
+source=(
+	"$_pkgbase::git+https://github.com/citra-emu/citra"
+	'git+https://github.com/citra-emu/ext-boost'
+	'git+https://github.com/neobrain/nihstro'
+	'git+https://github.com/citra-emu/ext-soundtouch'
+	'git+https://github.com/philsquared/Catch'
+	'git+https://github.com/MerryMage/dynarmic'
+	'git+https://github.com/herumi/xbyak'
+	'git+https://github.com/weidai11/cryptopp'
+	'git+https://github.com/fmtlib/fmt'
+	'git+https://github.com/lsalzman/enet'
+	'git+https://github.com/whoshuu/cpr'
+	'git+https://github.com/benhoyt/inih'
+)
+md5sums=(
+	'SKIP'
+	'SKIP'
+	'SKIP'
+	'SKIP'
+	'SKIP'
+	'SKIP'
+	'SKIP'
+	'SKIP'
+	'SKIP'
+	'SKIP'
+	'SKIP'
+	'SKIP'
+)
+
+pkgver() {
+	cd "$srcdir/$_pkgbase"
+	echo "r$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
+}
+
+prepare() {
+	cd "$srcdir/$_pkgbase"
+	mkdir -p build
+
+	git submodule init
+	git config submodule.boost.url "$srcdir/ext-boost"
+	git config submodule.nihstro.url "$srcdir/nihstro"
+	git config submodule.soundtouch.url "$srcdir/ext-soundtouch"
+	git config submodule.catch.url "$srcdir/Catch"
+	git config submodule.dynarmic.url "$srcdir/dynarmic"
+	git config submodule.xbyak.url "$srcdir/xbyak"
+	git config submodule.cryptopp.url "$srcdir/cryptopp"
+	git config submodule.fmt.url "$srcdir/fmt"
+	git config submodule.enet.url "$srcdir/enet"
+	git config submodule.cpr.url "$srcdir/cpr"
+	git config submodule.inih.url "$srcdir/inih"
+	git submodule update --init --recursive
+
+	cd externals/dynarmic
+	git config submodule.externals/fmt.url "$srcdir/fmt"
+	git config submodule.externals/xbyak.url "$srcdir/xbyak"
+	git submodule update --init --recursive
+}
+
+build() {
+	cd "$srcdir/$_pkgbase/build"
+	cmake .. -DCMAKE_INSTALL_PREFIX=/usr -DCMAKE_BUILD_TYPE=Release
+	make
+}
+
+package() {
+	cd "$srcdir/$_pkgbase/build"
+	install -Dm755 "src/citra/citra" "$pkgdir/usr/bin/citra"
+	install -Dm755 "src/citra_qt/citra-qt" "$pkgdir/usr/bin/citra-qt"
+}