Initial import into AUR 4

2 files changed, 67 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..b64782d24072
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,26 @@
+pkgbase = cjdns-git
+	pkgdesc = A routing engine designed for security, scalability, speed and ease of use
+	pkgver = 0.3.3357
+	pkgrel = 1
+	url = https://github.com/cjdelisle/cjdns
+	arch = i686
+	arch = x86_64
+	arch = arm
+	arch = armv6h
+	arch = armv7h
+	license = GPL3
+	makedepends = git
+	makedepends = nodejs
+	makedepends = python2
+	depends = glibc
+	optdepends = cjdnsify: allows you to run some programs bound to your cjdns address
+	optdepends = libnacl: speed up the build process by skipping the need to compile cnacl
+	optdepends = cjdns-git-sysvinit: support for sysvinit (rc.d)
+	options = !distcc
+	options = !strip
+	options = !buildflags
+	source = git+https://github.com/cjdelisle/cjdns#branch=crashey
+	sha512sums = SKIP
+
+pkgname = cjdns-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..800473b481a2
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,41 @@
+# Maintainer: Kevin MacMartin <prurigro@gmail.com>
+# Contributor: openfbt
+# Contributor: Werecat
+# Contributor: Xyne
+
+_pkgname=cjdns
+pkgname=$_pkgname-git
+pkgver=0.3.3357
+pkgrel=1
+pkgdesc='A routing engine designed for security, scalability, speed and ease of use'
+url='https://github.com/cjdelisle/cjdns'
+license=('GPL3')
+arch=('i686' 'x86_64' 'arm' 'armv6h' 'armv7h')
+options=('!distcc' '!strip' '!buildflags')
+depends=('glibc')
+makedepends=('git' 'nodejs' 'python2')
+optdepends=(
+  'cjdnsify: allows you to run some programs bound to your cjdns address'
+  'libnacl: speed up the build process by skipping the need to compile cnacl'
+  'cjdns-git-sysvinit: support for sysvinit (rc.d)'
+)
+source=("git+$url#branch=crashey")
+sha512sums=('SKIP')
+
+pkgver() {
+  cd $_pkgname
+  git describe --always | sed 's|-|.|g;s|[^\.]*\.||;s|\.[^\.]*$||'
+}
+
+build() {
+  cd $_pkgname
+  bash 'do'
+}
+
+package() {
+  cd $_pkgname
+  install -Dm755 'cjdroute' "$pkgdir/usr/bin/cjdroute"
+  install -Dm755 'contrib/sh/run-cjdroute.sh' "$pkgdir/usr/bin/run-cjdroute"
+  install -Dm644 "contrib/systemd/$_pkgname.service" "$pkgdir/usr/lib/systemd/system/$_pkgname.service"
+  install -Dm644 'doc/man/cjdroute.conf.5' "$pkgdir/usr/share/man/man5/cjdroute.conf.5"
+}