Add to AUR

2 files changed, 51 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..be47d8639263
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,19 @@
+pkgbase = contrast-git
+	pkgdesc = Check whether the contrast between two colors meets the WCAG requirements
+	pkgver = 0.0.3.r55.gb90638b
+	pkgrel = 1
+	url = https://gitlab.gnome.org/World/design/contrast
+	arch = x86_64
+	license = GPL3
+	makedepends = cmake
+	makedepends = git
+	makedepends = meson
+	makedepends = rust
+	depends = libhandy
+	provides = contrast
+	conflicts = contrast
+	source = git+https://gitlab.gnome.org/World/design/contrast.git
+	sha256sums = SKIP
+
+pkgname = contrast-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..230de55cdcce
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,32 @@
+# Maintainer: Caltlgin Stsodaat <contact@fossdaily.xyz>
+
+_pkgname='contrast'
+pkgname="${_pkgname}-git"
+pkgver=0.0.3.r55.gb90638b
+pkgrel=1
+pkgdesc='Check whether the contrast between two colors meets the WCAG requirements'
+arch=('x86_64')
+url='https://gitlab.gnome.org/World/design/contrast'
+license=('GPL3')
+depends=('libhandy')
+makedepends=('cmake' 'git' 'meson' 'rust')
+provides=("${_pkgname}")
+conflicts=("${_pkgname}")
+source=("git+${url}.git")
+sha256sums=('SKIP')
+
+pkgver() {
+  git -C "${_pkgname}" describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+  arch-meson "${_pkgname}" 'build'
+  meson compile -C 'build'
+}
+
+package() {
+  DESTDIR="${pkgdir}" meson install -C 'build'
+  install -Dvm644 "${_pkgname}/README.md" -t "${pkgdir}/usr/share/doc/${_pkgname}"
+}
+
+# vim: ts=2 sw=2 et: