initial commit

3 files changed, 119 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..b28ebd1c45cd
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,38 @@
+pkgbase = cosmic-session-git
+	pkgdesc = Session manager for the COSMIC desktop environment
+	pkgver = r123.8e73c0f
+	pkgrel = 1
+	url = https://github.com/pop-os/cosmic-session
+	arch = x86_64
+	arch = aarch64
+	groups = cosmic
+	license = GPL-3.0-or-later
+	makedepends = cargo
+	makedepends = git
+	makedepends = just
+	depends = cosmic-applibrary-git
+	depends = cosmic-applets-git
+	depends = cosmic-bg-git
+	depends = cosmic-comp-git
+	depends = cosmic-greeter-git
+	depends = cosmic-icons-git
+	depends = cosmic-launcher-git
+	depends = cosmic-notifications-git
+	depends = cosmic-osd-git
+	depends = cosmic-panel-git
+	depends = cosmic-randr-git
+	depends = cosmic-screenshot-git
+	depends = cosmic-settings-daemon-git
+	depends = cosmic-settings-git
+	depends = cosmic-workspaces-git
+	depends = xdg-desktop-portal-cosmic-git
+	optdepends = cosmic-edit-git: COSMIC text editor
+	optdepends = cosmic-files-git: COSMIC file manager
+	optdepends = cosmic-store-git: COSMIC store
+	optdepends = cosmic-term-git: COSMIC terminal
+	provides = cosmic-session
+	conflicts = cosmic-session
+	source = git+https://github.com/pop-os/cosmic-session.git
+	sha256sums = SKIP
+
+pkgname = cosmic-session-git
diff --git a/.gitignore b/.gitignore
new file mode 100644
index 000000000000..4dab8d6386e3
--- /dev/null
+++ b/.gitignore
@@ -0,0 +1,7 @@
+# Ignore everything
+*
+
+# But not these files...
+!.gitignore
+!PKGBUILD
+!.SRCINFO
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..297774219d93
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,74 @@
+# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
+pkgname=cosmic-session-git
+pkgver=r123.8e73c0f
+pkgrel=1
+pkgdesc="Session manager for the COSMIC desktop environment"
+arch=('x86_64' 'aarch64')
+url="https://github.com/pop-os/cosmic-session"
+license=('GPL-3.0-or-later')
+groups=('cosmic')
+depends=(
+  'cosmic-applibrary-git'
+  'cosmic-applets-git'
+  'cosmic-bg-git'
+  'cosmic-comp-git'
+  'cosmic-greeter-git'
+  'cosmic-icons-git'
+  'cosmic-launcher-git'
+  'cosmic-notifications-git'
+  'cosmic-osd-git'
+  'cosmic-panel-git'
+  'cosmic-randr-git'
+  'cosmic-screenshot-git'
+  'cosmic-settings-daemon-git'
+  'cosmic-settings-git'
+  'cosmic-workspaces-git'
+  'xdg-desktop-portal-cosmic-git'
+)
+makedepends=(
+  'cargo'
+  'git'
+  'just'
+)
+checkdepends=()
+optdepends=(
+  'cosmic-edit-git: COSMIC text editor'
+  'cosmic-files-git: COSMIC file manager'
+  'cosmic-store-git: COSMIC store'
+  'cosmic-term-git: COSMIC terminal'
+)
+provides=("${pkgname%-git}")
+conflicts=("${pkgname%-git}")
+replaces=()
+backup=()
+options=()
+install=
+source=('git+https://github.com/pop-os/cosmic-session.git')
+sha256sums=('SKIP')
+
+pkgver() {
+  cd "${pkgname%-git}"
+  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+prepare() {
+  cd "${pkgname%-git}"
+  export CARGO_HOME="$srcdir/cargo-home"
+  export RUSTUP_TOOLCHAIN=stable
+  cargo fetch --target "$CARCH-unknown-linux-gnu"
+}
+
+build() {
+  cd "${pkgname%-git}"
+  export CARGO_HOME="$srcdir/cargo-home"
+  export RUSTUP_TOOLCHAIN=stable
+  just all
+
+  # libexec > lib
+  sed -i 's|libexec|lib|g' Justfile src/main.rs
+}
+
+package() {
+  cd "${pkgname%-git}"
+  just rootdir="$pkgdir" install
+}