Initial commit

2 files changed, 52 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..c9205d390cd7
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,16 @@
+pkgbase = cs-crypto-git
+	pkgdesc = C++ interface for calling existing cryptography libraries (git version)
+	pkgver = 1.0.1.r0.gbd87d67
+	pkgrel = 1
+	url = https://www.copperspice.com/
+	arch = x86_64
+	license = BSD
+	makedepends = git
+	makedepends = cmake
+	makedepends = catch2
+	provides = cs-crypto
+	conflicts = cs-crypto
+	source = git+https://github.com/copperspice/cs_crypto.git
+	sha256sums = SKIP
+
+pkgname = cs-crypto-git
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..57d752299dc0
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,36 @@
+# Maintainer: Daniel Bermond <dbermond@archlinux.org>
+
+pkgname=cs-crypto-git
+pkgver=1.0.1.r0.gbd87d67
+pkgrel=1
+pkgdesc='C++ interface for calling existing cryptography libraries (git version)'
+arch=('x86_64')
+url='https://www.copperspice.com/'
+license=('BSD')
+makedepends=('git' 'cmake' 'catch2')
+provides=('cs-crypto')
+conflicts=('cs-crypto')
+source=('git+https://github.com/copperspice/cs_crypto.git')
+sha256sums=('SKIP')
+
+pkgver() {
+    git -C cs_crypto describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/^crypto\.//;s/^v//'
+}
+
+build() {
+    cmake -B build -S cs_crypto \
+        -DCMAKE_BUILD_TYPE:STRING='None' \
+        -DCMAKE_INSTALL_PREFIX:PATH='/usr' \
+        -DBUILD_TESTS:BOOL='ON' \
+        -Wno-dev
+    make -C build
+}
+
+check() {
+    make -C build test
+}
+
+package() {
+    DESTDIR="$pkgdir" cmake --install build
+    install -D -m644 cs_crypto/LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
+}