Initial upload

3 files changed, 102 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..cdf8ecb51808
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,25 @@
+pkgbase = curl-http2-git
+	pkgdesc = A URL retrieval utility and library (HTTP/2 enabled)
+	pkgver = 7.45.0.32.g257a1c0
+	pkgrel = 1
+	url = http://curl.haxx.se/
+	arch = i686
+	arch = x86_64
+	license = MIT
+	makedepends = git
+	depends = zlib
+	depends = libssh2
+	depends = openssl
+	depends = ca-certificates
+	depends = nghttp2
+	provides = curl=999
+	conflicts = curl
+	conflicts = curl-git
+	options = !libtool
+	source = git://github.com/bagder/curl.git
+	source = curlbuild.h
+	md5sums = SKIP
+	md5sums = 751bd433ede935c8fae727377625a8ae
+
+pkgname = curl-http2-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..7033cabfd8f4
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,68 @@
+# Maintainer: Christoph Krapp <headlock@its-crap.de>
+# Orig-Maintainer: Dave Reisner <d@falconindy.com>
+
+pkgname=curl-http2-git
+pkgver=7.45.0.32.g257a1c0
+pkgrel=1
+pkgdesc="A URL retrieval utility and library (HTTP/2 enabled)"
+arch=('i686' 'x86_64')
+url="http://curl.haxx.se/"
+license=('MIT')
+depends=('zlib' 'libssh2' 'openssl' 'ca-certificates' 'nghttp2')
+makedepends=('git')
+provides=('curl=999')
+conflicts=('curl' 'curl-git')
+options=('!libtool')
+source=('git://github.com/bagder/curl.git'
+        'curlbuild.h')
+md5sums=('SKIP'
+         '751bd433ede935c8fae727377625a8ae')
+
+pkgver() {
+  # curl-7_30_0-101-gf4e6e20
+  cd curl
+
+  git describe | sed 's/curl-//; s/[_-]/./g'
+}
+
+build() {
+  cd curl
+
+  ./buildconf
+  ./configure \
+      --prefix=/usr \
+      --mandir=/usr/share/man \
+      --disable-ldap \
+      --disable-ldaps \
+      --enable-ipv6 \
+      --enable-manual \
+      --enable-versioned-symbols \
+      --enable-threaded-resolver \
+      --without-libidn \
+      --with-random=/dev/urandom \
+      --with-nghttp2=/usr \
+      --with-ca-bundle=/etc/ssl/certs/ca-certificates.crt
+
+  make
+}
+
+package() {
+  cd curl
+
+  make DESTDIR="$pkgdir" install
+
+  local ptrsize=$(cpp <<<'__SIZEOF_POINTER__' | sed '/^#/d')
+  case $ptrsize in
+    8) _curlbuild=curlbuild-64.h ;;
+    4) _curlbuild=curlbuild-32.h ;;
+    *) error "unknown pointer size for architecture: %s bytes" "$ptrsize"
+      exit 1
+      ;;
+  esac
+
+  install -Dm644 docs/libcurl/libcurl.m4 $pkgdir/usr/share/aclocal/libcurl.m4
+  mv "$pkgdir/usr/include/curl/curlbuild.h" "$pkgdir/usr/include/curl/$_curlbuild"
+  install -m 644 $srcdir/curlbuild.h "$pkgdir/usr/include/curl/curlbuild.h"
+
+  install -Dm644 COPYING $pkgdir/usr/share/licenses/$pkgname/COPYING
+}
diff --git a/curlbuild.h b/curlbuild.h
new file mode 100644
index 000000000000..b48862696c60
--- /dev/null
+++ b/curlbuild.h
@@ -0,0 +1,9 @@
+#include <bits/wordsize.h>
+
+#if __WORDSIZE == 32
+#include "curlbuild-32.h"
+#elif __WORDSIZE == 64
+#include "curlbuild-64.h"
+#else
+#error "Unknown word size"
+#endif