update

2 files changed, 73 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..c5557e9cba86
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,28 @@
+pkgbase = deepin-session-shell-git
+	pkgdesc = Deepin desktop-environment - session-shell module
+	pkgver = 5.3.0.3.r0.g47dba80
+	pkgrel = 1
+	url = https://github.com/linuxdeepin/dde-session-shell
+	arch = x86_64
+	groups = deepin-git
+	license = GPL3
+	makedepends = git
+	makedepends = cmake
+	makedepends = ninja
+	makedepends = qt5-tools
+	depends = deepin-daemon
+	depends = deepin-qt5integration-git
+	depends = deepin-wallpapers
+	depends = gsettings-qt
+	depends = liblightdm-qt5
+	depends = startdde
+	provides = lightdm-deepin-greeter
+	provides = deepin-session-shell
+	conflicts = deepin-session-ui<5
+	conflicts = deepin-session-shell
+	replaces = deepin-session-shell
+	source = git://github.com/linuxdeepin/dde-session-shell
+	sha512sums = SKIP
+
+pkgname = deepin-session-shell-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..32da3335e10f
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,45 @@
+# Maintainer: DingYuan Zhang <justforlxz@gmail.com>
+
+pkgname=deepin-session-shell-git
+pkgver=5.3.0.3.r0.g47dba80
+pkgrel=1
+pkgdesc='Deepin desktop-environment - session-shell module'
+arch=('x86_64')
+url="https://github.com/linuxdeepin/dde-session-shell"
+license=('GPL3')
+depends=('deepin-daemon' 'deepin-qt5integration-git' 'deepin-wallpapers' 'gsettings-qt' 'liblightdm-qt5'
+         'startdde')
+makedepends=('git' 'cmake' 'ninja' 'qt5-tools')
+conflicts=('deepin-session-ui<5' 'deepin-session-shell')
+provides=('lightdm-deepin-greeter' 'deepin-session-shell')
+replaces=('deepin-session-shell')
+groups=('deepin-git')
+source=("git://github.com/linuxdeepin/dde-session-shell")
+sha512sums=('SKIP')
+
+pkgver() {
+    cd dde-session-shell
+    git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+prepare() {
+  cd dde-session-shell
+  sed -i '/darrowrectangle/d' CMakeLists.txt src/widgets/widgets.pri
+  sed -i '1i#include <QPainterPath>' src/widgets/useravatar.cpp
+
+  # We don't have common-auth on Arch
+  sed -i 's/common-auth/system-login/' src/libdde-auth/authagent.cpp
+}
+
+build() {
+  cd dde-session-shell
+  cmake . -GNinja -DCMAKE_INSTALL_PREFIX=/usr
+  ninja
+}
+
+package() {
+  cd dde-session-shell
+  DESTDIR="$pkgdir" ninja install
+
+  chmod +x "$pkgdir"/usr/bin/deepin-greeter
+}