fixup and unify PKGBUILD with official repository variant

- adjust dependencies accordingly
- enforce GPG signatures, all commits nowadays must be signed
- use better pkgver function to reflect tag+revisions
- quote $pkgdir properly as it may contain spaces
- use style of official repo variant to have minimal diff

1 files changed, 27 insertions, 19 deletions

diff --git a/PKGBUILD b/PKGBUILD
index 6019a3fe1d48..080a56b1ebf6 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,36 +1,44 @@
 # Maintainer: Brian Bidulock <bidulock@openss7.org>
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
 
 pkgname=devtools-git
-_pkgname=devtools
-pkgver=20200213
+pkgver=20200407
 pkgrel=1
 pkgdesc='Tools for Arch Linux package maintainers'
 arch=('any')
 license=('GPL')
 url='https://git.archlinux.org/devtools.git/'
-depends=('namcap' 'openssh' 'subversion' 'rsync' 'arch-install-scripts'
-         'git' 'bzr' 'mercurial')
-makedepends=('asciidoc' 'git')
-provides=($_pkgname=$pkgver)
-conflicts=($_pkgname)
-source=("$pkgname::git+https://git.archlinux.org/devtools.git")
-md5sums=('SKIP')
+depends=('bash' 'openssh' 'subversion' 'rsync' 'arch-install-scripts'
+         'git' 'bzr' 'mercurial' 'diffutils' 'util-linux' 'awk')
+makedepends=('asciidoc')
+optdepends=('btrfs-progs: btrfs support')
+provides=('devtools')
+conflicts=('devtools')
+source=("git+https://git.archlinux.org/devtools.git?signed")
+validpgpkeys=('487EACC08557AD082088DABA1EB2638FF56C0C53'
+              '4AA4767BBC9C4B1D18AE28B77F2D434B9741E8AC'
+              '86CFFCA918CF3AF47147588051E8B148A9999C34'
+              '8FC15A064950A99DD1BD14DD39E4B877E62EB915'
+              '8218F88849AAC522E94CF470A5E9288C4FA415FA'
+              'B81B051F2D7FC867AAFF35A58DBD63B82072D77A'
+              'F3691687D867B81B51CE07D9BBE43771487328A9'
+              '6645B0A8C7005E78DB1D7864F99FFE0FEAE999BD'
+              'E240B57E2C4630BA768E2F26FC1B547C8D8172C8')
+sha512sums=('SKIP')
 
 pkgver() {
-	cd ${pkgname}
-	git show -s --format=%ci HEAD^{commit}|awk '{print$1}'|sed 's,-,,g'
-}
-
-prepare() {
-	cd ${pkgname}
+  cd ${pkgname/-git/}
+  git describe --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
 }
 
 build() {
-	cd ${pkgname}
-	make PREFIX=/usr
+  cd ${pkgname/-git/}
+  make PREFIX=/usr
 }
 
 package() {
-	cd ${pkgname}
-	make PREFIX=/usr DESTDIR=${pkgdir} install
+  cd ${pkgname/-git/}
+  make PREFIX=/usr DESTDIR="${pkgdir}" install
 }
+
+# vim: ts=2 sw=2 et: