Initial commit

2 files changed, 114 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..9b76ac5f6137
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,33 @@
+pkgbase = discord-development-electron-bin
+	pkgdesc = Discord Development (popular voice + video app) using the system provided electron for increased security and performance
+	pkgver = 0.0.143
+	pkgrel = 1
+	url = https://discordapp.com
+	arch = x86_64
+	license = custom
+	makedepends = asar
+	depends = electron
+	depends = gtk3
+	depends = libnotify
+	depends = libxss
+	depends = glibc
+	depends = alsa-lib
+	depends = nspr
+	depends = nss
+	depends = xdg-utils
+	depends = libcups
+	optdepends = libpulse: Pulseaudio support
+	optdepends = xdg-utils: Open files
+	optdepends = noto-fonts-emoji: Google font for emoji support.
+	optdepends = ttf-symbola: Font for emoji support.
+	optdepends = noto-fonts-cjk: Font for special characters such as /shrug face.
+	provides = discord-development
+	conflicts = discord-development
+	source = https://dl-development.discordapp.net/apps/linux/0.0.143/discord-development-0.0.143.tar.gz
+	source = LICENSE.html::https://discordapp.com/terms
+	source = OSS-LICENSES.html::https://discordapp.com/licenses
+	b2sums = cee148b5c41f77dfdd6459856ebb72e99c2d00c0c8583555dde54ccea901eef94aa7dd620cde6bf8248af6863932a88676267c9bf02dfef479ebd04ca8b1b37f
+	b2sums = 216cef029383f20a85d802bdc5a462f79ba1a3c2200b008c51c87091167527461c457fbd93b3e23d1f1e9fc6eb993a1c41181d6e1798bd753f1cf17a4310fc16
+	b2sums = c98282efbf3e4699d84992e615ed55ddcde375c2b96de99e6085b7196ffc0eb182b6d1193857020319449927a19febef25210771a86e212583d871b93bdc8514
+
+pkgname = discord-development-electron-bin
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..032b5c88cdb1
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,81 @@
+# Maintained by Kodehawa <david.alejandro.rubio at gmail.com>
+
+# Original discord_arch_electron PKGBUILD:
+# Maintained by johnnyapol (arch@johnnyapol.me)
+
+# Original mantainers below:
+# Based off the discord community repo PKGBUILD by Filipe Laíns (FFY00) <lains@archlinux.org>
+# Maintainer: Anna <morganamilo@gmail.com>
+# Maintainer: E5ten <e5ten.arch@gmail.com>
+# Maintainer: Parker Reed <parker.l.reed@gmail.com>
+# Maintainer: Stephanie Wilde-Hobbs <steph@rx14.co.uk>
+# Contributor: Cayde Dixon <me@cazzar.net>
+# Contributor: Anthony Anderson <aantony4122@gmail.com>
+
+pkgname=discord-development-electron-bin
+_pkgname=discord-development
+pkgver=0.0.143
+pkgrel=1
+pkgdesc="Discord Development (popular voice + video app) using the system provided electron for increased security and performance"
+arch=('x86_64')
+provides=('discord-development')
+conflicts=('discord-development')
+url='https://discordapp.com'
+license=('custom')
+depends=('electron' 'gtk3' 'libnotify' 'libxss' 'glibc' 'alsa-lib' 'nspr' 'nss' 'xdg-utils' 'libcups')
+makedepends=('asar')
+optdepends=('libpulse: Pulseaudio support'
+            'xdg-utils: Open files'
+            'noto-fonts-emoji: Google font for emoji support.'
+            'ttf-symbola: Font for emoji support.'
+            'noto-fonts-cjk: Font for special characters such as /shrug face.')
+source=("https://dl-development.discordapp.net/apps/linux/${pkgver}/${_pkgname}-${pkgver}.tar.gz"
+        'LICENSE.html::https://discordapp.com/terms'
+        'OSS-LICENSES.html::https://discordapp.com/licenses')
+# Skip SHA256 of licenses, it fails always for some reason.
+b2sums=('cee148b5c41f77dfdd6459856ebb72e99c2d00c0c8583555dde54ccea901eef94aa7dd620cde6bf8248af6863932a88676267c9bf02dfef479ebd04ca8b1b37f'
+        '216cef029383f20a85d802bdc5a462f79ba1a3c2200b008c51c87091167527461c457fbd93b3e23d1f1e9fc6eb993a1c41181d6e1798bd753f1cf17a4310fc16'
+        'c98282efbf3e4699d84992e615ed55ddcde375c2b96de99e6085b7196ffc0eb182b6d1193857020319449927a19febef25210771a86e212583d871b93bdc8514')
+
+# The tar extracts to a folder called DiscordCanary.
+_tarname=DiscordDevelopment
+
+prepare() {
+  # Extract the downloaded tar.
+  tar xf ${_pkgname}-${pkgver}.tar.gz
+  cd $_tarname
+
+  sed -i "s|Exec=.*|Exec=/usr/bin/$_pkgname|" $_pkgname.desktop
+  echo 'Path=/usr/bin' >> $_pkgname.desktop
+}
+
+package() {
+  # Install the app
+  install -d "$pkgdir"/usr/lib/$_pkgname
+  
+  # HACKS FOR SYSTEM ELECTRON
+  # Thanks to the discord_arch_electron guy for this ;)
+  # Thanks to https://aur.archlinux.org/packages/discord_arch_electron/#comment-776307 for the less-hacky fix.
+  asar e $_tarname/resources/app.asar $_tarname/resources/app
+  sed -i "s|process.resourcesPath|'/usr/lib/$_pkgname'|" $_tarname/resources/app/app_bootstrap/buildInfo.js
+  sed -i "s|exeDir,|'/usr/share/pixmaps',|" $_tarname/resources/app/app_bootstrap/autoStart/linux.js
+  asar p $_tarname/resources/app $_tarname/resources/app.asar --unpack-dir '**'
+  rm -rf $_tarname/resources/app 
+  
+  # Copy relevant data
+  cp -r "$_tarname"/resources/*  "$pkgdir"/usr/lib/$_pkgname/
+  
+  # Create starter script for discord
+  echo "#!/bin/sh" >> "$srcdir"/$_pkgname
+  echo "exec electron /usr/lib/$_pkgname/app.asar \$@" >> "$srcdir"/$_pkgname
+  
+  install -d "$pkgdir"/usr/{bin,share/{pixmaps,applications}}
+  install -Dm 755 $_pkgname "$pkgdir"/usr/bin/$_pkgname
+  
+  cp $_tarname/discord.png "$pkgdir"/usr/share/pixmaps/$_pkgname.png
+  cp $_tarname/$_pkgname.desktop "$pkgdir"/usr/share/applications/$_pkgname.desktop
+  
+  # Licenses
+  install -Dm 644 LICENSE.html "$pkgdir"/usr/share/licenses/$pkgname/LICENSE.html
+  install -Dm 644 OSS-LICENSES.html "$pkgdir"/usr/share/licenses/$pkgname/OSS-LICENSES.html
+}