Initial commit

2 files changed, 52 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..d5bd57b19241
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,18 @@
+pkgbase = discordrp-mpris-git
+	pkgdesc = Discord Rich Presence based on mpris2 media players
+	pkgver = 0.1.0.r0.g775cea3
+	pkgrel = 1
+	url = https://github.com/FichteFoll/discordrp-mpris
+	arch = any
+	license = MIT
+	makedepends = git
+	depends = python
+	depends = python-setuptools
+	depends = python-dbussy
+	provides = discordrp-mpris
+	conflicts = discordrp-mpris
+	source = git+https://github.com/FichteFoll/discordrp-mpris.git
+	sha256sums = SKIP
+
+pkgname = discordrp-mpris-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..1bc607020fe4
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,34 @@
+# Maintainer: FichteFoll <fichtefoll2@googlemail.com>
+
+_pkgbase=discordrp-mpris
+# _name=${_pkgbase#python-}
+pkgname="${_pkgbase}-git"
+pkgver=0.1.0.r0.g775cea3
+pkgrel=1
+pkgdesc="Discord Rich Presence based on mpris2 media players"
+arch=(any)
+url="https://github.com/FichteFoll/discordrp-mpris"
+license=('MIT')
+depends=('python' 'python-setuptools' 'python-dbussy')
+makedepends=('git')
+provides=("${_pkgbase}")
+conflicts=("${_pkgbase}")
+source=("git+https://github.com/FichteFoll/discordrp-mpris.git")
+sha256sums=('SKIP')
+
+pkgver() {
+    cd "${srcdir}/${_pkgbase}"
+    (
+        set -o pipefail
+        git describe --long --tags 2>/dev/null | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g' ||
+        printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+    )
+}
+
+package() {
+    cd "${srcdir}/${_pkgbase}"
+    python setup.py install --root="$pkgdir/" --optimize=1
+
+    install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    install -D -m644 discordrp-mpris.service "${pkgdir}/usr/lib/systemd/user/discordrp-mpris.service"
+}