January 2020 beta

2 files changed, 120 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..fe1122ff0400
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,49 @@
+pkgbase = dolphin-emu-beta-git
+	pkgdesc = A GameCube / Wii / Triforce emulator - monhtly beta release
+	pkgver = 5.0.r11608.69ee15e5ef
+	pkgrel = 1
+	url = http://www.dolphin-emu.org/
+	arch = x86_64
+	license = GPL
+	makedepends = cmake
+	makedepends = git
+	makedepends = libglvnd
+	makedepends = python
+	depends = alsa-lib
+	depends = bluez-libs
+	depends = enet
+	depends = hidapi
+	depends = libevdev
+	depends = libgl
+	depends = libpng
+	depends = libpulse
+	depends = libx11
+	depends = libxi
+	depends = libxrandr
+	depends = lzo
+	depends = mbedtls
+	depends = pugixml
+	depends = qt5-base
+	depends = sfml
+	depends = zlib
+	depends = libavcodec.so
+	depends = libavformat.so
+	depends = libavutil.so
+	depends = libcurl.so
+	depends = libminiupnpc.so
+	depends = libswscale.so
+	depends = libudev.so
+	depends = libusb-1.0.so
+	depends = libxxhash.so
+	optdepends = pulseaudio: PulseAudio backend
+	options = !emptydirs
+	source = dolphin-emu::git+https://github.com/dolphin-emu/dolphin.git#commit=69ee15e5ef369d51681540e6714f02554e3bd8a6
+	sha256sums = SKIP
+
+pkgname = dolphin-emu-beta-git
+	provides = dolphin-emu
+	conflicts = dolphin-emu
+
+pkgname = dolphin-emu-beta-nogui-git
+	depends = dolphin-emu-beta-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..5c0d42834f08
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,71 @@
+# Maintainer: ThaChillera ThaChillera@protonmail.com
+# Contributor: Maxime Gauduin <alucryd@archlinux.org>
+# Contributor: Lightning <sgsdxzy@gmail.com>
+
+# latest version optaind from this API endpoint: https://dolphin-emu.org/update/latest/beta/
+pkgbase=dolphin-emu-beta-git
+pkgname=('dolphin-emu-beta-git' 'dolphin-emu-beta-nogui-git')
+pkgver=5.0.r11608.69ee15e5ef
+pkgrel=1
+pkgdesc='A GameCube / Wii / Triforce emulator - monhtly beta release'
+arch=('x86_64')
+url='http://www.dolphin-emu.org/'
+license=('GPL')
+depends=(
+  'alsa-lib' 'bluez-libs' 'enet' 'hidapi' 'libevdev' 'libgl' 'libpng'
+  'libpulse' 'libx11' 'libxi' 'libxrandr' 'lzo' 'mbedtls' 'pugixml' 'qt5-base'
+  'sfml' 'zlib'
+  'libavcodec.so' 'libavformat.so' 'libavutil.so' 'libcurl.so'
+  'libminiupnpc.so' 'libswscale.so' 'libudev.so' 'libusb-1.0.so' 'libxxhash.so'
+)
+makedepends=('cmake' 'git' 'libglvnd' 'python')
+optdepends=('pulseaudio: PulseAudio backend')
+options=('!emptydirs')
+source=('dolphin-emu::git+https://github.com/dolphin-emu/dolphin.git#commit=69ee15e5ef369d51681540e6714f02554e3bd8a6')
+sha256sums=('SKIP')
+
+pkgver() {
+  cd dolphin-emu
+
+  git describe | sed 's/-/.r/; s/-g/./'
+}
+
+prepare() {
+  if [[ -d build ]]; then
+    rm -rf build
+  fi
+  mkdir build
+}
+
+build() {
+  cd build
+
+  cmake ../dolphin-emu \
+    -DCMAKE_INSTALL_PREFIX='/usr' \
+    -DCMAKE_INSTALL_LIBDIR='/usr/lib' \
+    -DENABLE_QT='TRUE' \
+    -DUSE_SHARED_ENET='TRUE' \
+    -DXXHASH_FOUND='TRUE'\
+    -DDISTRIBUTOR='aur.archlinux.org'
+  make
+}
+
+package_dolphin-emu-beta-git() {
+  provides=('dolphin-emu')
+  conflicts=('dolphin-emu')
+
+  make DESTDIR="${pkgdir}" -C build install
+  rm "${pkgdir}"/usr/bin/dolphin-emu-nogui
+  rm -rf "${pkgdir}"/usr/{include,lib/libdiscord-rpc.a}
+
+  install -Dm 644 dolphin-emu/Data/51-usb-device.rules -t "${pkgdir}"/usr/lib/udev/rules.d/
+}
+
+package_dolphin-emu-beta-nogui-git() {
+  depends=('dolphin-emu-beta-git')
+
+  install -dm 755 "${pkgdir}"/usr/bin
+  install -m 755 build/Binaries/dolphin-emu-nogui "${pkgdir}"/usr/bin/dolphin-emu-cli
+}
+
+# vim: ts=2 sw=2 et: