newpkg: dpkg-git 1.19.4.r5.g42bf88145-1

2 files changed, 67 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..4d76c8b2844a
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,23 @@
+pkgbase = dpkg-git
+	pkgdesc = Debian package management system
+	pkgver = 1.19.4.r5.g42bf88145
+	pkgrel = 1
+	url = https://tracker.debian.org/pkg/dpkg
+	arch = i686
+	arch = x86_64
+	license = GPL
+	makedepends = git
+	makedepends = perl-io-string
+	makedepends = perl-timedate
+	depends = glibc
+	depends = bzip2
+	depends = perl
+	depends = xz
+	depends = zlib
+	provides = dpkg
+	conflicts = dpkg
+	source = git+https://git.dpkg.org/git/dpkg/dpkg.git
+	sha256sums = SKIP
+
+pkgname = dpkg-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..20e2a4dcab16
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,44 @@
+# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
+
+pkgname=dpkg-git
+pkgver=1.19.4.r5.g42bf88145
+pkgrel=1
+pkgdesc="Debian package management system"
+arch=('i686' 'x86_64')
+url="https://tracker.debian.org/pkg/dpkg"
+license=('GPL')
+depends=('glibc' 'bzip2' 'perl' 'xz' 'zlib')
+makedepends=('git' 'perl-io-string' 'perl-timedate')
+provides=('dpkg')
+conflicts=('dpkg')
+source=("git+https://git.dpkg.org/git/dpkg/dpkg.git")
+sha256sums=('SKIP')
+
+
+pkgver() {
+  cd "dpkg"
+
+  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+  cd "dpkg"
+
+  ./autogen
+  ./configure \
+    --prefix="/usr" \
+    --sbindir="/usr/bin" \
+    --sysconfdir="/etc" \
+    --localstatedir="/var" \
+    --disable-start-stop-daemon
+  make
+}
+
+package() {
+  cd "dpkg"
+
+  make DESTDIR="$pkgdir" install
+
+  install -d "$pkgdir/var/dpkg/updates"
+  touch "$pkgdir/var/lib/dpkg"/{status,available}
+}