First commit

2 files changed, 52 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..566950846fa1
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,15 @@
+pkgbase = dyna-git
+	pkgdesc = Convert a colorscheme from one terminal emulator to another.
+	pkgver = 0.1.1.r13.g96545ad
+	pkgrel = 1
+	url = https://git.sr.ht/~grtcdr/dyna
+	arch = x86_64
+	license = MIT
+	makedepends = git
+	makedepends = cargo
+	provides = dyna
+	conflicts = dyna
+	source = dyna::git+https://git.sr.ht/~grtcdr/dyna
+	sha1sums = SKIP
+
+pkgname = dyna-git
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..264c355fea87
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,37 @@
+# Maintainer: Jason Nader <jason.nader@protonmail.com>
+
+pkgname=dyna-git
+pkgver=0.1.1.r13.g96545ad
+pkgrel=1
+pkgdesc='Convert a colorscheme from one terminal emulator to another.'
+arch=('x86_64')
+url='https://git.sr.ht/~grtcdr/dyna'
+license=('MIT')
+makedepends=('git' 'cargo')
+provides=("${pkgname%-*}")
+conflicts=("${pkgname%-*}")
+source=("${pkgname%-*}::git+$url")
+sha1sums=('SKIP')
+
+pkgver() {
+  cd "${pkgname%-*}"
+  echo $(grep '^version =' Cargo.toml|head -n1|cut -d\" -f2).r$(git rev-list --count HEAD).g$(git describe --always)
+}
+
+prepare() {
+  cd "${pkgname%-*}"
+  cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
+}
+
+build() {
+  cd "${pkgname%-*}"
+  export RUSTUP_TOOLCHAIN=stable
+  export CARGO_TARGET_DIR=target
+  cargo build --release
+}
+
+package() {
+  cd "${pkgname%-*}"
+  install -Dm755 -t "${pkgdir}/usr/bin" "target/release/${pkgname%-*}"
+  install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname%-*}/LICENSE"
+}