Initial upload, bring changes since 0.51 online

3 files changed, 75 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..7d6ae132acf1
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,22 @@
+pkgbase = dyndnsc-git
+	pkgdesc = Dynamic DNS client with support for multiple protocols and services. Compatible with IPv6 dual stack. Git version
+	pkgver = 0.5.1.r24.g59ef5f9
+	pkgrel = 1
+	url = https://pypi.org/project/dyndnsc
+	arch = any
+	license = MIT
+	makedepends = git
+	depends = python-requests
+	depends = python-setuptools
+	depends = python-netifaces
+	depends = python-dnspython
+	depends = python-daemonocle
+	provides = dyndnsc
+	conflicts = dyndnsc
+	source = git+https://github.com/infothrill/python-dyndnsc.git
+	source = dyndnsc.service
+	md5sums = SKIP
+	md5sums = 530304e7ce3c6463c0d0d053949ad5a9
+
+pkgname = dyndnsc-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..1b5dbf905859
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,41 @@
+# Maintainer: Taijian <taijian@posteo.de>
+# Contributor: Malstrond <malstrond@gmail.com>
+# Contributor: xduugu
+
+pkgname=dyndnsc-git
+_pkgbase=python-dyndnsc
+pkgver=0.5.1.r24.g59ef5f9
+pkgrel=1
+pkgdesc="Dynamic DNS client with support for multiple protocols and services. Compatible with IPv6 dual stack. Git version"
+arch=('any')
+url="https://pypi.org/project/dyndnsc"
+license=('MIT')
+depends=('python-requests' 'python-setuptools' 'python-netifaces' 'python-dnspython' 'python-daemonocle')
+makedepends=('git')
+provides=('dyndnsc')
+conflicts=('dyndnsc')
+source=("git+https://github.com/infothrill/python-dyndnsc.git"
+        'dyndnsc.service')
+md5sums=('SKIP'
+         '530304e7ce3c6463c0d0d053949ad5a9')
+
+pkgver() {
+  cd "$_pkgbase"
+  git describe --long --tags | sed 's/-/.r/;s/-/./'
+}
+
+build() {
+    cd "$_pkgbase"
+    python setup.py build
+}
+
+package() {
+    cd "$_pkgbase"
+    python setup.py install --root="$pkgdir" --optimize=1
+
+    # install systemd service file
+    install -Dm644 "$srcdir/dyndnsc.service" "$pkgdir/usr/lib/systemd/system/dyndnsc.service"
+
+    # install license file
+    install -Dm644 "LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
diff --git a/dyndnsc.service b/dyndnsc.service
new file mode 100644
index 000000000000..cb80111bbf6c
--- /dev/null
+++ b/dyndnsc.service
@@ -0,0 +1,12 @@
+[Unit]
+Description=dyndnsc
+After=network.target
+
+[Service]
+ExecStart=/usr/bin/dyndnsc --loop --config /etc/dyndnsc.conf
+Restart=always
+ProtectSystem=strict
+ProtectHome=true
+
+[Install]
+WantedBy=multi-user.target