3.34.2

2 files changed, 65 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..94174af76011
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,21 @@
+pkgbase = ebadoo-shell-extensions
+	pkgdesc = Extensions for EBADOO shell, including classic mode
+	pkgver = 3.34.2
+	pkgrel = 1
+	url = https://wiki.gnome.org/Projects/GnomeShell/Extensions
+	arch = any
+	groups = ebadoo-desktop
+	license = GPL
+	makedepends = meson
+	makedepends = git
+	makedepends = sassc
+	makedepends = js60
+	optdepends = gnome-menus: applications menu extension
+	source = git+https://gitlab.com/ebadoo/ebadoo-shell-extensions.git
+	source = git+https://gitlab.gnome.org/GNOME/gnome-shell-sass.git
+	sha256sums = SKIP
+	sha256sums = SKIP
+
+pkgname = ebadoo-shell-extensions
+	depends = ebadoo-shell
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..78c2752c2e63
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,44 @@
+# Maintainer: Fernando Guevara <admin@ebadoo.com>
+
+pkgname=ebadoo-shell-extensions
+pkgver=3.34.2
+pkgrel=1
+pkgdesc="Extensions for EBADOO shell, including classic mode"
+url="https://wiki.gnome.org/Projects/GnomeShell/Extensions"
+arch=(any)
+license=(GPL)
+makedepends=(meson git sassc js60)
+optdepends=('gnome-menus: applications menu extension')
+groups=(ebadoo-desktop)
+source=("git+https://gitlab.com/ebadoo/ebadoo-shell-extensions.git"
+        "git+https://gitlab.gnome.org/GNOME/gnome-shell-sass.git")
+sha256sums=('SKIP'
+            'SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+
+  git submodule init
+  git config --local submodule.data/gnome-shell-sass.url "$srcdir/gnome-shell-sass"
+  git submodule update
+}
+
+build() {
+  arch-meson $pkgname build -D extension_set=all -D classic_mode=true
+  ninja -C build
+}
+
+check() {
+  meson test -C build --print-errorlogs
+}
+
+package() {
+  depends=(ebadoo-shell)
+
+  DESTDIR="$pkgdir" meson install -C build
+}