init, alpha 1

Signed-off-by: Yurii Kolesnykov <root@yurikoles.com>

3 files changed, 95 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..e9a50066a529
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,35 @@
+pkgbase = electron20-bin
+	pkgdesc = Build cross platform desktop apps with web technologies - binary version 20
+	pkgver = 20.0.0.alpha.1
+	pkgrel = 1
+	url = https://electronjs.org/
+	arch = x86_64
+	arch = aarch64
+	license = MIT
+	depends = c-ares
+	depends = ffmpeg
+	depends = gtk3
+	depends = libevent
+	depends = libxslt
+	depends = minizip
+	depends = nss
+	depends = re2
+	depends = snappy
+	optdepends = kde-cli-tools: file deletion support (kioclient5)
+	optdepends = libappindicator-gtk3: StatusNotifierItem support
+	optdepends = pipewire: WebRTC desktop sharing under Wayland
+	optdepends = trash-cli: file deletion support (trash-put)
+	optdepends = xdg-utils: open URLs with desktop's default (xdg-email, xdg-open)
+	provides = electron20=20.0.0.alpha.1
+	provides = electron=20.0.0.alpha.1
+	conflicts = electron20
+	source_x86_64 = electron20-bin-chromedriver-20.0.0.alpha.1-1-x86_64.zip::https://github.com/electron/electron/releases/download/v20.0.0-alpha.1/chromedriver-v20.0.0-alpha.1-linux-x64.zip
+	source_x86_64 = electron20-bin-20.0.0.alpha.1-1-x86_64.zip::https://github.com/electron/electron/releases/download/v20.0.0-alpha.1/electron-v20.0.0-alpha.1-linux-x64.zip
+	sha256sums_x86_64 = 17a7f25a94500bd952e7d9490fa19d2f2e436a878973d018ce8f522727d5a2bc
+	sha256sums_x86_64 = b8635125d53e099b5dd06f2adefdc50249f3c39ff4c61558af23294d866ec562
+	source_aarch64 = electron20-bin-chromedriver-20.0.0.alpha.1-1-aarch64.zip::https://github.com/electron/electron/releases/download/v20.0.0-alpha.1/chromedriver-v20.0.0-alpha.1-linux-arm64.zip
+	source_aarch64 = electron20-bin-20.0.0.alpha.1-1-aarch64.zip::https://github.com/electron/electron/releases/download/v20.0.0-alpha.1/electron-v20.0.0-alpha.1-linux-arm64.zip
+	sha256sums_aarch64 = 7af6871916a13beed0b92d2ebd9698973cb3748b90996e77f4dd75d43aef11eb
+	sha256sums_aarch64 = 6da5c8675bb24e78507861eedb680309035dd29dda5443ec3283d19996fe78fa
+
+pkgname = electron20-bin
diff --git a/.gitignore b/.gitignore
new file mode 100644
index 000000000000..dfdac5afc0ff
--- /dev/null
+++ b/.gitignore
@@ -0,0 +1,5 @@
+*.zip
+src/
+*.log
+pkg/
+*.pkg.*
\ No newline at end of file
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..4bc98b85bffb
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,55 @@
+# Maintainer: Yurii Kolesnykov <root@yurikoles.com>
+# based on aur electron8-bin: Tom Vincent <http://tlvince.com/contact/>
+
+_projectname=electron
+_major=20
+_pkgname="${_projectname}${_major}"
+pkgname="${_pkgname}"-bin
+_alpha=1
+_pkgver="${_major}.0.0-alpha.${_alpha}"
+pkgver="${_pkgver/-/.}"
+pkgrel=1
+pkgdesc="Build cross platform desktop apps with web technologies - binary version ${_major}"
+arch=('x86_64' 'aarch64')
+url=https://electronjs.org/
+license=('MIT')
+provides=("${_pkgname}=${pkgver}" "${_projectname}=${pkgver}")
+conflicts=("${_pkgname}")
+depends=('c-ares' 'ffmpeg' 'gtk3' 'libevent' 'libxslt' 'minizip' 'nss' 're2'
+         'snappy')
+optdepends=('kde-cli-tools: file deletion support (kioclient5)'
+            'libappindicator-gtk3: StatusNotifierItem support'
+            'pipewire: WebRTC desktop sharing under Wayland'
+            'trash-cli: file deletion support (trash-put)'
+            "xdg-utils: open URLs with desktop's default (xdg-email, xdg-open)")
+_releaseurl="https://github.com/${_projectname}/${_projectname}/releases/download/v${_pkgver}"
+source_x86_64=(
+	"${pkgname}-chromedriver-${pkgver}-${pkgrel}-x86_64.zip::${_releaseurl}/chromedriver-v${_pkgver}-linux-x64.zip"
+	"${pkgname}-${pkgver}-${pkgrel}-x86_64.zip::${_releaseurl}/${_projectname}-v${_pkgver}-linux-x64.zip"
+)
+source_aarch64=(
+	"${pkgname}-chromedriver-${pkgver}-${pkgrel}-aarch64.zip::${_releaseurl}/chromedriver-v${_pkgver}-linux-arm64.zip"
+	"${pkgname}-${pkgver}-${pkgrel}-aarch64.zip::${_releaseurl}/${_projectname}-v${_pkgver}-linux-arm64.zip"
+)
+sha256sums_x86_64=('17a7f25a94500bd952e7d9490fa19d2f2e436a878973d018ce8f522727d5a2bc'
+                   'b8635125d53e099b5dd06f2adefdc50249f3c39ff4c61558af23294d866ec562')
+sha256sums_aarch64=('7af6871916a13beed0b92d2ebd9698973cb3748b90996e77f4dd75d43aef11eb'
+                    '6da5c8675bb24e78507861eedb680309035dd29dda5443ec3283d19996fe78fa')
+
+package() {
+	install -dm755 "${pkgdir}/usr/lib/${_pkgname}/"
+	find . -mindepth 1 -maxdepth 1 -type f ! -name "*.zip" ! -name "LICENSE*" -exec cp -r --no-preserve=ownership --preserve=mode -t "${pkgdir}/usr/lib/${_pkgname}/." {} +
+
+	for _folder in 'locales' 'resources'; do
+		cp -r --no-preserve=ownership --preserve=mode "${_folder}/" "${pkgdir}/usr/lib/${_pkgname}/${_folder}/"
+	done
+
+	chmod u+s "${pkgdir}/usr/lib/${_pkgname}/chrome-sandbox"
+
+	install -dm755 "${pkgdir}/usr/bin"
+	ln -nfs "/usr/lib/${_pkgname}/${_projectname}" "${pkgdir}/usr/bin/${_pkgname}"
+
+	for _license in 'LICENSE' 'LICENSES.chromium.html'; do
+		install -Dm644 "${_license}" "${pkgdir}/usr/share/licenses/${pkgname}/${_license}"
+	done
+}