Added electron5-bin

4 files changed, 130 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..07c23aa41fce
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,45 @@
+pkgbase = electron5-bin
+	pkgdesc = Build cross platform desktop apps with web technologies - version 5 - binary version
+	pkgver = 5.0.13
+	pkgrel = 1
+	url = https://electronjs.org
+	arch = x86_64
+	arch = i686
+	arch = armv7h
+	arch = aarch64
+	license = MIT
+	depends = c-ares
+	depends = ffmpeg
+	depends = gtk3
+	depends = http-parser
+	depends = libevent
+	depends = libnghttp2
+	depends = libxslt
+	depends = libxss
+	depends = minizip
+	depends = nss
+	depends = re2
+	depends = snappy
+	optdepends = kde-cli-tools: file deletion support (kioclient5)
+	optdepends = trash-cli: file deletion support (trash-put)
+	optdepends = xdg-utils: open URLs with desktop's default (xdg-email, xdg-open)
+	provides = electron5
+	conflicts = electron5
+	source_x86_64 = electron5-bin-chromedriver-5.0.13-1-x86_64.zip::https://github.com/electron/electron/releases/download/v5.0.13/chromedriver-v5.0.13-linux-x64.zip
+	source_x86_64 = electron5-bin-5.0.13-1-x86_64.zip::https://github.com/electron/electron/releases/download/v5.0.13/electron-v5.0.13-linux-x64.zip
+	sha256sums_x86_64 = 4af6c27b38a2afce2cec6195e1a2541f963d4c6536fd8ca38c634381117d7fd5
+	sha256sums_x86_64 = 8ded43241c4b7a6f04f2ff21c75ae10e4e6db1794e8b1b4f7656c0ed21667f8f
+	source_i686 = electron5-bin-chromedriver-5.0.13-1-i686.zip::https://github.com/electron/electron/releases/download/v5.0.13/chromedriver-v5.0.13-linux-ia32.zip
+	source_i686 = electron5-bin-5.0.13-1-i686.zip::https://github.com/electron/electron/releases/download/v5.0.13/electron-v5.0.13-linux-ia32.zip
+	sha256sums_i686 = 7c55fc6eafc0ff7368f5afc55af06d94589cfa93bf9273c3f629b688f097c2b4
+	sha256sums_i686 = ccf4a5ed226928a30bd3ea830913d99853abb089bd4a6299ffa9fa0daa8d026a
+	source_armv7h = electron5-bin-chromedriver-5.0.13-1-armv7h.zip::https://github.com/electron/electron/releases/download/v5.0.13/chromedriver-v5.0.13-linux-armv7l.zip
+	source_armv7h = electron5-bin-5.0.13-1-armv7h.zip::https://github.com/electron/electron/releases/download/v5.0.13/electron-v5.0.13-linux-armv7l.zip
+	sha256sums_armv7h = de67346716501f66c6ba880adda58b338cd14397d82d59f99d9a19206d1d06fc
+	sha256sums_armv7h = 96ad83802bc61d87bb952027d49e5dd297f58e4493e66e393b26e51e09065add
+	source_aarch64 = electron5-bin-chromedriver-5.0.13-1-aarch64.zip::https://github.com/electron/electron/releases/download/v5.0.13/chromedriver-v5.0.13-linux-arm64.zip
+	source_aarch64 = electron5-bin-5.0.13-1-aarch64.zip::https://github.com/electron/electron/releases/download/v5.0.13/electron-v5.0.13-linux-arm64.zip
+	sha256sums_aarch64 = 153332ccd57678913eb602ec0f44cf3c5be57578c13b92672827b24784cfda76
+	sha256sums_aarch64 = 01f0fd313b060fb28a1022d68fb224d415fa22986e2a8f4aded6424b65e35add
+
+pkgname = electron5-bin
diff --git a/.editorconfig b/.editorconfig
new file mode 100644
index 000000000000..a467ee9a97a6
--- /dev/null
+++ b/.editorconfig
@@ -0,0 +1,8 @@
+root = true
+
+[*]
+charset = utf-8
+end_of_line = lf
+insert_final_newline = true
+indent_style = tab
+tab_width = 4
diff --git a/.gitignore b/.gitignore
new file mode 100644
index 000000000000..82b3c183d5d4
--- /dev/null
+++ b/.gitignore
@@ -0,0 +1,14 @@
+# from https://github.com/github/gitignore/blob/master/ArchLinuxPackages.gitignore
+*.tar
+*.tar.*
+*.rpm
+*.jar
+*.exe
+*.msi
+*.zip
+*.tgz
+*.log
+*.log.*
+*.sig
+
+*/
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..930b4820653f
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,63 @@
+# Maintainer: Daniel Peukert <dan.peukert@gmail.com>
+# Contributor: Matthew McGinn <mamcgi@gmail.com>
+_projectname='electron'
+_pkgname="${_projectname}5"
+pkgname="$_pkgname-bin"
+pkgver='5.0.13'
+pkgrel='1'
+pkgdesc='Build cross platform desktop apps with web technologies - version 5 - binary version'
+arch=('x86_64' 'i686' 'armv7h' 'aarch64')
+url="https://${_projectname}js.org"
+license=('MIT')
+provides=("$_pkgname")
+conflicts=("$_pkgname")
+depends=('c-ares' 'ffmpeg' 'gtk3' 'http-parser' 'libevent' 'libnghttp2' 'libxslt' 'libxss' 'minizip' 'nss' 're2' 'snappy')
+optdepends=(
+	'kde-cli-tools: file deletion support (kioclient5)'
+	'trash-cli: file deletion support (trash-put)'
+	"xdg-utils: open URLs with desktop's default (xdg-email, xdg-open)"
+)
+_releaseurl="https://github.com/$_projectname/$_projectname/releases/download/v$pkgver"
+source_x86_64=(
+	"$pkgname-chromedriver-$pkgver-$pkgrel-x86_64.zip::$_releaseurl/chromedriver-v$pkgver-linux-x64.zip"
+	"$pkgname-$pkgver-$pkgrel-x86_64.zip::$_releaseurl/$_projectname-v$pkgver-linux-x64.zip"
+)
+source_i686=(
+	"$pkgname-chromedriver-$pkgver-$pkgrel-i686.zip::$_releaseurl/chromedriver-v$pkgver-linux-ia32.zip"
+	"$pkgname-$pkgver-$pkgrel-i686.zip::$_releaseurl/$_projectname-v$pkgver-linux-ia32.zip"
+)
+source_armv7h=(
+	"$pkgname-chromedriver-$pkgver-$pkgrel-armv7h.zip::$_releaseurl/chromedriver-v$pkgver-linux-armv7l.zip"
+	"$pkgname-$pkgver-$pkgrel-armv7h.zip::$_releaseurl/$_projectname-v$pkgver-linux-armv7l.zip"
+)
+source_aarch64=(
+	"$pkgname-chromedriver-$pkgver-$pkgrel-aarch64.zip::$_releaseurl/chromedriver-v$pkgver-linux-arm64.zip"
+	"$pkgname-$pkgver-$pkgrel-aarch64.zip::$_releaseurl/$_projectname-v$pkgver-linux-arm64.zip"
+)
+sha256sums_x86_64=('4af6c27b38a2afce2cec6195e1a2541f963d4c6536fd8ca38c634381117d7fd5'
+                   '8ded43241c4b7a6f04f2ff21c75ae10e4e6db1794e8b1b4f7656c0ed21667f8f')
+sha256sums_i686=('7c55fc6eafc0ff7368f5afc55af06d94589cfa93bf9273c3f629b688f097c2b4'
+                 'ccf4a5ed226928a30bd3ea830913d99853abb089bd4a6299ffa9fa0daa8d026a')
+sha256sums_armv7h=('de67346716501f66c6ba880adda58b338cd14397d82d59f99d9a19206d1d06fc'
+                   '96ad83802bc61d87bb952027d49e5dd297f58e4493e66e393b26e51e09065add')
+sha256sums_aarch64=('153332ccd57678913eb602ec0f44cf3c5be57578c13b92672827b24784cfda76'
+                    '01f0fd313b060fb28a1022d68fb224d415fa22986e2a8f4aded6424b65e35add')
+
+package() {
+	cd "$srcdir/"
+	install -dm755 "$pkgdir/usr/lib/$_pkgname/"
+	find . -mindepth 1 -maxdepth 1 -type f ! -name "*.zip" ! -name "LICENSE*" -exec cp -r --no-preserve=ownership --preserve=mode -t "$pkgdir/usr/lib/$_pkgname/." {} +
+
+	for _folder in 'locales' 'resources' 'swiftshader'; do
+		cp -r --no-preserve=ownership --preserve=mode "$_folder/" "$pkgdir/usr/lib/$_pkgname/$_folder/"
+	done
+
+	chmod u+s "$pkgdir/usr/lib/$_pkgname/chrome-sandbox"
+
+	install -dm755 "$pkgdir/usr/bin"
+	ln -nfs "/usr/lib/$_pkgname/$_projectname" "$pkgdir/usr/bin/$_pkgname"
+
+	for _license in 'LICENSE' 'LICENSES.chromium.html'; do
+		install -Dm644 "$_license" "$pkgdir/usr/share/licenses/$pkgname/$_license"
+	done
+}