v=2.25.4190.102.20201110,r=1

2 files changed, 86 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..99b753db6440
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,25 @@
+pkgbase = emacs-mozc-ut
+	pkgdesc = Mozc module for Emacs bundled with the UT dictionary
+	pkgver = 2.25.4190.102.20201110
+	pkgrel = 1
+	url = https://github.com/google/mozc
+	arch = i686
+	arch = x86_64
+	license = custom
+	makedepends = clang
+	makedepends = git
+	makedepends = gtk2
+	makedepends = ninja
+	makedepends = pkgconf
+	makedepends = python
+	makedepends = qt5-base
+	depends = emacs
+	depends = mozc-ut-common
+	provides = emacs-mozc=2.25.4190.102
+	conflicts = emacs-mozc
+	conflicts = emacs-mozc-ut2
+	source = emacs-mozc-ut-git::git+https://github.com/google/mozc.git#commit=cfd05a0907d4ff95a15cc6fe2d4d56ed480f4002
+	sha256sums = SKIP
+
+pkgname = emacs-mozc-ut
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..8785c6694e07
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,61 @@
+# Maintainer: Nocifer <apmichalopoulos at gmail dot com>
+# Based on original PKGBUILD by: UTUMI Hirosi <utuhiro78 at yahoo dot co dot jp>
+# Contributor: Felix Yan <felixonmars@gmail.com>
+# Contributor: ponsfoot <cabezon dot hashimoto at gmail dot com>
+
+
+## The UT dictionary's upstream url: 'http://linuxplayers.g1.xrea.com/mozc-ut.html'
+
+
+## Helpful internal stuff
+_commit=cfd05a0907d4ff95a15cc6fe2d4d56ed480f4002
+_mozcver=2.25.4190.102
+_utdicdate=20201110
+_utdicrel=1
+_bldtype=Release
+
+pkgname='emacs-mozc-ut'
+pkgver=${_mozcver}.${_utdicdate}
+pkgrel=1
+pkgdesc='Mozc module for Emacs bundled with the UT dictionary'
+arch=('i686' 'x86_64')
+url='https://github.com/google/mozc'
+license=('custom')
+depends=('emacs' 'mozc-ut-common')
+makedepends=('clang' 'git' 'gtk2' 'ninja' 'pkgconf' 'python' 'qt5-base')
+conflicts=('emacs-mozc' 'emacs-mozc-ut2')
+provides=("emacs-mozc=${_mozcver}")
+source=("${pkgname}-git::git+https://github.com/google/mozc.git#commit=${_commit}")
+sha256sums=('SKIP')
+
+prepare() {
+    cd ${pkgname}-git
+
+    git submodule update --init --recursive
+
+    # Avoid build errors (don't use libc++)
+    # These should probably be included as options in GYP_DEFINES
+    sed -i -e 's/-stdlib=libc++//' src/gyp/common.gypi
+    sed -i -e 's/-lc++//' src/gyp/common.gypi
+}
+
+build() {
+    cd ${pkgname}-git/src
+
+    _targets='unix/emacs/emacs.gyp:mozc_emacs_helper'
+
+    GYP_DEFINES='document_dir=/usr/share/licenses/mozc'
+
+    python build_mozc.py gyp --target_platform=Linux
+    python build_mozc.py build -c ${_bldtype} ${_targets}
+}
+
+package() {
+    cd ${pkgname}-git/src
+
+    install -Dm644 ../LICENSE                                           ${pkgdir}/usr/share/licenses/mozc/emacs-mozc
+    install -Dm644 data/installer/credits_en.html                       ${pkgdir}/usr/share/licenses/mozc/emacs-mozc-submodules
+
+    install -Dm755 out_linux/${_bldtype}/mozc_emacs_helper              ${pkgdir}/usr/bin/mozc_emacs_helper
+    install -Dm644 unix/emacs/mozc.el                                   ${pkgdir}/usr/share/emacs/site-lisp/mozc.el
+}