Initial build (0.5.1)

3 files changed, 74 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..3d00675f59db
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,20 @@
+pkgbase = envio-git
+	pkgdesc = A Modern And Secure CLI Tool For Managing Environment Variables
+	pkgver = 0.5.1.r58.ge94d20e
+	pkgrel = 1
+	url = https://envio-cli.github.io/home
+	arch = any
+	license = Apache-2.0
+	license = MIT
+	makedepends = git
+	makedepends = cargo
+	depends = glibc
+	depends = gcc-libs
+	depends = gpgme
+	depends = libgpg-error
+	provides = envio=0.5.1
+	conflicts = envio
+	source = envio::git+https://github.com/envio-cli/envio.git
+	sha256sums = SKIP
+
+pkgname = envio-git
diff --git a/.gitignore b/.gitignore
new file mode 100644
index 000000000000..018a3de08144
--- /dev/null
+++ b/.gitignore
@@ -0,0 +1,4 @@
+*
+!PKGBUILD
+!.SRCINFO
+!.gitignore
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..9c2e513c21c9
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,50 @@
+# Maintainer: vitaliikuzhdin <vitaliikuzhdin@gmail.com>
+
+_pkgname="envio"
+pkgname="${_pkgname}-git"
+pkgver=0.5.1.r58.ge94d20e
+pkgrel=1
+pkgdesc="A Modern And Secure CLI Tool For Managing Environment Variables"
+arch=('any')
+url="https://envio-cli.github.io/home"
+_url="https://github.com/envio-cli/${_pkgname}"
+license=('Apache-2.0' 'MIT')
+depends=('glibc' 'gcc-libs' 'gpgme' 'libgpg-error')
+makedepends=('git' 'cargo')
+provides=("${_pkgname}=${pkgver%%.r*}")
+conflicts=("${_pkgname}")
+_pkgsrc="${_pkgname}"
+source=("${_pkgsrc}::git+${_url}.git")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd "${_pkgsrc}"
+  git describe --long --tags --abbrev=7 | sed 's/v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+prepare() {
+  cd "${srcdir}/${_pkgsrc}"
+  export RUSTUP_TOOLCHAIN=stable
+  cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
+}
+
+build() {
+  cd "${srcdir}/${_pkgsrc}"
+  export RUSTUP_TOOLCHAIN=stable
+  export CARGO_TARGET_DIR=target
+  cargo build --frozen --release --all-features
+}
+
+check() {
+  cd "${srcdir}/${_pkgsrc}"
+  export RUSTUP_TOOLCHAIN=stable
+  cargo test --frozen --all-features
+}
+
+package() {
+  cd "${srcdir}/${_pkgsrc}"
+  install -Dm755 "target/release/${_pkgname}" "${pkgdir}/usr/bin/${_pkgname}"
+  install -Dm644 "README.md" "${pkgdir}/usr/share/doc/${_pkgname}/README.md"
+  install -Dm644 "LICENSE-APACHE" "${pkgdir}/usr/share/licenses/${_pkgname}/LICENSE-APACHE-2.0"
+  install -Dm644 "LICENSE-MIT" "${pkgdir}/usr/share/licenses/${_pkgname}/LICENSE-MIT"
+}