drive-by fixes & improvements

2 files changed, 40 insertions, 22 deletions

diff --git a/.SRCINFO b/.SRCINFO
index 3db12d93ebff..9434a9164a83 100644
--- a/.SRCINFO
+++ b/.SRCINFO
@@ -1,21 +1,25 @@
 pkgbase = evillimiter-git
 	pkgdesc = Tool that monitors, analyzes and limits the bandwidth of devices on the local network without administrative access.
 	pkgver = 1.5.0.r0.g46d2033
-	pkgrel = 1
+	pkgrel = 2
 	url = https://github.com/bitbrute/evillimiter
 	arch = any
 	license = MIT
 	makedepends = git
-	makedepends = python-setuptools
+	makedepends = python-build
+	makedepends = python-installer
+	makedepends = python-wheel
+	depends = glibc
 	depends = python-colorama
 	depends = python-netaddr
 	depends = python-netifaces
 	depends = python-tqdm
 	depends = python-scapy
+	depends = python-setuptools
 	depends = python-terminaltables
 	provides = evillimiter
-	source = git+https://github.com/bitbrute/evillimiter.git#branch=master
+	conflicts = evillimiter
+	source = git+https://github.com/bitbrute/evillimiter.git
 	sha256sums = SKIP
 
 pkgname = evillimiter-git
-
diff --git a/PKGBUILD b/PKGBUILD
index 2a6ec81ff862..8dd25e34d938 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,37 +1,51 @@
-# Maintainer: Jay Ta'ala <jay@jaytaala.com>
-# Contributor: Mark Wagie <mark dot wagie at tutanota dot com>
+# Maintainer: 
+# Contributor: Jay Ta'ala <jay@jaytaala.com>
+# Contributor: Mark Wagie <mark dot wagie at proton dot me>
 # Contributor: YaYPIXXO <viggo@lekdorf.com>
 pkgname=evillimiter-git
 pkgver=1.5.0.r0.g46d2033
-pkgrel=1
+pkgrel=2
 pkgdesc="Tool that monitors, analyzes and limits the bandwidth of devices on the local network without administrative access."
 arch=('any')
 url="https://github.com/bitbrute/evillimiter"
 license=('MIT')
-provides=('evillimiter')
-depends=('python-colorama' 'python-netaddr' 'python-netifaces' 'python-tqdm'
-         'python-scapy' 'python-terminaltables')
-makedepends=('git' 'python-setuptools')
-source=("git+https://github.com/bitbrute/evillimiter.git#branch=master")
+depends=(
+  'glibc'
+  'python-colorama'
+  'python-netaddr'
+  'python-netifaces'
+  'python-tqdm'
+  'python-scapy'
+  'python-setuptools'
+  'python-terminaltables'
+)
+makedepends=(
+  'git'
+  'python-build'
+  'python-installer'
+  'python-wheel'
+)
+provides=("${pkgname%-git}")
+conflicts=("${pkgname%-git}")
+source=('git+https://github.com/bitbrute/evillimiter.git')
 sha256sums=('SKIP')
 
 pkgver() {
-	cd "${srcdir}/evillimiter/"
-	git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+  cd "${pkgname%-git}"
+  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
 }
 
 build() {
-	cd "${srcdir}/evillimiter/"
-	python setup.py build
+  cd "${pkgname%-git}"
+  python -m build --wheel --no-isolation
 }
 
 package() {
-	cd "${srcdir}/evillimiter/"
-	export PYTHONHASHSEED=0
-	python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+  cd "${pkgname%-git}"
+  python -m installer --destdir="$pkgdir" dist/*.whl
 
-	install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
+  install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
 
-	# Fix LIBC issue
-	ln -sf /usr/lib/libc.a "$pkgdir/usr/lib/liblibc.a"
+  # Fix LIBC issue
+  ln -sf /usr/lib/libc.a "$pkgdir/usr/lib/liblibc.a"
 }