Initial import

2 files changed, 55 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..fcb7a6eb04eb
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,19 @@
+pkgbase = extension-manager-git
+	pkgdesc = A native tool for browsing, installing, and managing GNOME Shell Extensions
+	pkgver = r34.a10a0ce
+	pkgrel = 1
+	url = https://github.com/mjakeman/extension-manager
+	arch = x86_64
+	license = GPL3
+	checkdepends = appstream-glib
+	makedepends = meson
+	makedepends = blueprint-compiler-git
+	depends = gtk4
+	depends = libadwaita
+	depends = json-glib
+	provides = extension-manager
+	conflicts = extension-manager
+	source = git+https://github.com/mjakeman/extension-manager.git
+	b2sums = SKIP
+
+pkgname = extension-manager-git
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..fcb48a29a6c0
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,36 @@
+# Maintainer: Your Name <youremail@domain.com>
+pkgname=extension-manager-git
+pkgver=r34.a10a0ce
+pkgrel=1
+pkgdesc="A native tool for browsing, installing, and managing GNOME Shell Extensions"
+arch=('x86_64')
+url="https://github.com/mjakeman/extension-manager"
+license=('GPL3')
+depends=('gtk4' 'libadwaita' 'json-glib')
+makedepends=('meson' 'blueprint-compiler-git')
+checkdepends=('appstream-glib')
+provides=("${pkgname%-git}")
+conflicts=("${pkgname%-git}")
+source=(git+$url.git)
+b2sums=('SKIP')
+
+pkgver() {
+  cd "${pkgname%-git}"
+  ( set -o pipefail
+    git describe --long 2>/dev/null | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g' ||
+    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+  )
+}
+
+build() {
+  arch-meson "${pkgname%-git}" build
+  meson compile -C build
+}
+
+check() {
+  meson test -C build
+}
+
+package() {
+  meson install -C build --destdir "$pkgdir"
+}