File-roller with elementary OS patches, such as contracts

2 files changed, 72 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..11145c0a47f4
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,33 @@
+pkgbase = file-roller-pantheon
+	pkgdesc = Archive manipulator for GNOME (with elementary OS patches)
+	pkgver = 3.28.0+1ubuntu1+r4.4ab5e02aa
+	pkgrel = 1
+	url = https://gitlab.gnome.org/GNOME/file-roller/
+	arch = i686
+	arch = x86_64
+	groups = pantheon
+	license = GPL
+	makedepends = yelp-tools
+	makedepends = git
+	makedepends = libnautilus-extension
+	makedepends = meson
+	makedepends = appstream-glib
+	depends = gtk3
+	depends = dconf
+	depends = libarchive
+	depends = file
+	depends = json-glib
+	depends = libnotify
+	depends = zip
+	depends = unzip
+	optdepends = p7zip: 7z, arj, exe and encrypted zip files support
+	optdepends = unrar: better RAR archive support
+	optdepends = unace: ACE archive support
+	optdepends = lrzip: lrzip archive support
+	provides = file-roller=3.28.0+1ubuntu1+r4.4ab5e02aa
+	conflicts = file-roller
+	source = git+https://github.com/elementary/os-patches.git#branch=file-roller-bionic-patched
+	sha256sums = SKIP
+
+pkgname = file-roller-pantheon
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..f6496fbb0e0b
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,39 @@
+# Maintainer: Que Quotion <quequotion@bugmenot.com>
+# Contributor: Adria Arrufat <adria DOT arrufat+aur AT protonmail DOT ch>
+
+pkgname=file-roller-pantheon
+pkgver=3.28.0+1ubuntu1+r4.4ab5e02aa
+pkgrel=1
+pkgdesc="Archive manipulator for GNOME (with elementary OS patches)"
+url="https://gitlab.gnome.org/GNOME/file-roller/"
+arch=('i686' 'x86_64')
+license=('GPL')
+depends=(gtk3 dconf libarchive file json-glib libnotify zip unzip)
+makedepends=(yelp-tools git libnautilus-extension meson appstream-glib)
+optdepends=('p7zip: 7z, arj, exe and encrypted zip files support'
+            'unrar: better RAR archive support'
+            'unace: ACE archive support'
+            'lrzip: lrzip archive support')
+groups=(pantheon)
+provides=(file-roller="${pkgver}")
+conflicts=(file-roller)
+source=("git+https://github.com/elementary/os-patches.git#branch=file-roller-bionic-patched")
+sha256sums=('SKIP')
+
+pkgver() {
+    cd "os-patches"
+
+    printf "3.28.0+1ubuntu1+r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+build() {
+    cd "os-patches"
+    [ -d build ] && rm -rf build
+    arch-meson build
+    ninja -C build
+}
+
+package() {
+    cd "os-patches"
+    DESTDIR="${pkgdir}" ninja -C build install
+}