newpkg: findutils-git 4.6.0.r115.g9530e31f-1

2 files changed, 67 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..f2a4c86a17f4
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,21 @@
+pkgbase = findutils-git
+	pkgdesc = Basic directory searching utilities of the GNU operating system
+	pkgver = 4.6.0.r115.g9530e31f
+	pkgrel = 1
+	url = https://www.gnu.org/software/findutils/
+	arch = i686
+	arch = x86_64
+	license = GPL3
+	checkdepends = dejagnu
+	makedepends = git
+	makedepends = gettext
+	depends = glibc
+	depends = sh
+	provides = findutils
+	conflicts = findutils
+	options = staticlibs
+	source = git+https://git.savannah.gnu.org/git/findutils.git
+	sha256sums = SKIP
+
+pkgname = findutils-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..d44df32370e1
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,46 @@
+# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
+
+pkgname=findutils-git
+pkgver=4.6.0.r115.g9530e31f
+pkgrel=1
+pkgdesc="Basic directory searching utilities of the GNU operating system"
+arch=('i686' 'x86_64')
+url="https://www.gnu.org/software/findutils/"
+license=('GPL3')
+depends=('glibc' 'sh')
+makedepends=('git' 'gettext')
+checkdepends=('dejagnu')
+provides=('findutils')
+conflicts=('findutils')
+options=('staticlibs')
+source=("git+https://git.savannah.gnu.org/git/findutils.git")
+sha256sums=('SKIP')
+
+
+pkgver() {
+  cd "findutils"
+
+  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+  cd "findutils"
+
+  ./bootstrap
+
+  sed -i '/^SUBDIRS/s/locate//' Makefile.in
+  ./configure --prefix="/usr"
+  make
+}
+
+check() {
+  cd "findutils"
+
+  make check
+}
+
+package() {
+  cd "findutils"
+
+  make DESTDIR="$pkgdir" install
+}