Initial commit

2 files changed, 55 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..0f5441d14496
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,23 @@
+pkgbase = five-or-more-git
+	pkgdesc = Remove colored balls from the board by forming lines
+	pkgver = 3.32.0+56+gbe9877f
+	pkgrel = 1
+	url = https://wiki.gnome.org/Apps/Five%20or%20more
+	arch = x86_64
+	license = GPL
+	makedepends = gobject-introspection
+	makedepends = yelp-tools
+	makedepends = appstream-glib
+	makedepends = git
+	makedepends = meson
+	makedepends = vala
+	depends = gtk3
+	depends = librsvg
+	depends = libgnome-games-support
+	provides = five-or-more
+	conflicts = five-or-more
+	source = git+https://gitlab.gnome.org/GNOME/five-or-more.git
+	sha512sums = SKIP
+
+pkgname = five-or-more-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..04a3b144a351
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,32 @@
+pkgname=five-or-more-git
+_pkgname=five-or-more
+pkgver=3.32.0+56+gbe9877f
+pkgrel=1
+pkgdesc="Remove colored balls from the board by forming lines"
+url="https://wiki.gnome.org/Apps/Five%20or%20more"
+arch=(x86_64)
+license=(GPL)
+depends=('gtk3' 'librsvg' 'libgnome-games-support')
+makedepends=('gobject-introspection' 'yelp-tools' 'appstream-glib' 'git' 'meson' 'vala')
+provides=('five-or-more')
+conflicts=('five-or-more')
+source=("git+https://gitlab.gnome.org/GNOME/five-or-more.git")
+sha512sums=('SKIP')
+
+pkgver() {
+  cd $_pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+build() {
+  arch-meson $_pkgname build
+  ninja -C build
+}
+
+check() {
+  meson test -C build --print-errorlogs
+}
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+}