initial commit

2 files changed, 64 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..c435cd5a6ec0
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,16 @@
+pkgbase = flexvdi-client-appimage
+	pkgdesc = Client for connecting to flexVDI desktops
+	pkgver = 3.1.6
+	pkgrel = 1
+	url = https://flexvdi.com/en/downloads
+	arch = x86_64
+	license = custom:Unlicense
+	depends = zlib
+	depends = hicolor-icon-theme
+	noextract = flexvdi-client-appimage-3.1.6-x86_64.AppImage
+	options = !strip
+	source_x86_64 = flexvdi-client-appimage-3.1.6-x86_64.AppImage::http://depot.flexvdi.com/clients/linux-x86_64/flexvdi-client-3.1.6-x86_64.AppImage
+	md5sums_x86_64 = 2507624190a5015e75d7ed989be7bd93
+
+pkgname = flexvdi-client-appimage
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..9752fca3339d
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,48 @@
+# Maintainer: Chee Sing Lee <cheesinglee@gmail.com>
+
+_pkgname=flexvdi-client
+
+pkgname="${_pkgname}"-appimage
+pkgver=3.1.6
+pkgrel=1
+pkgdesc="Client for connecting to flexVDI desktops"
+arch=('x86_64')
+url="https://flexvdi.com/en/downloads"
+license=('custom:Unlicense')
+depends=('zlib' 'hicolor-icon-theme')
+options=(!strip)
+_appimage="${pkgname}-${pkgver}-x86_64.AppImage"
+source_x86_64=("${_appimage}::http://depot.flexvdi.com/clients/linux-x86_64/flexvdi-client-${pkgver}-x86_64.AppImage")
+noextract=("${_appimage}")
+md5sums_x86_64=('2507624190a5015e75d7ed989be7bd93')
+
+prepare() {
+    chmod +x "${_appimage}"
+    ./"${_appimage}" --appimage-extract
+}
+
+build() {
+    # Adjust .desktop so it will work outside of AppImage container
+    sed -i -E "s|Exec=flexvdi-client|Exec=env DESKTOPINTEGRATION=false /usr/bin/${_pkgname}|"\
+        "squashfs-root/${_pkgname}.desktop"
+    sed -i -E "s|Icon=icon|Icon=flexvdi-client|" "squashfs-root/${_pkgname}.desktop"
+    # Fix permissions; .AppImage permissions are 700 for all directories
+    chmod -R a-x+rX squashfs-root/
+}
+
+package() {
+    # AppImage
+    install -Dm755 "${srcdir}/${_appimage}" "${pkgdir}/opt/${pkgname}/${pkgname}.AppImage"
+
+    # Desktop file
+    install -Dm644 "${srcdir}/squashfs-root/${_pkgname}.desktop"\
+            "${pkgdir}/usr/share/applications/${_pkgname}.desktop"
+
+    # Icon images
+    install -dm755 "${pkgdir}/usr/share/icons/hicolor/256x256/apps/"
+    cp -a "${srcdir}/squashfs-root/icon.png" "${pkgdir}/usr/share/icons/hicolor/256x256/apps/flexvdi-client.png"
+
+    # Symlink executable
+    install -dm755 "${pkgdir}/usr/bin"
+    ln -s "/opt/${pkgname}/${pkgname}.AppImage" "${pkgdir}/usr/bin/${_pkgname}"
+}