Initial import

2 files changed, 69 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..4b9cb4a9c6b0
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,23 @@
+pkgbase = freeciv-git
+	pkgdesc = A multiuser clone of the famous Microprose game of Civilization
+	pkgver = r23947.b487f15267
+	pkgrel = 1
+	url = http://www.freeciv.org/
+	arch = x86_64
+	license = GPL2
+	makedepends = python
+	depends = curl
+	depends = gtk3
+	depends = lua
+	depends = qt5-base
+	depends = sdl2_gfx
+	depends = sdl2_image
+	depends = sdl2_mixer
+	depends = sdl2_ttf
+	provides = freeciv
+	conflicts = freeciv
+	source = git+https://github.com/freeciv/freeciv.git
+	sha256sums = SKIP
+
+pkgname = freeciv-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..c9340cd8895f
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,46 @@
+# Maintainer: Rodrigo Bezerra <rodrigobezerra21 at gmail dot com>
+
+_basename=freeciv
+pkgname=freeciv-git
+pkgver=r23947.b487f15267
+pkgrel=1
+pkgdesc="A multiuser clone of the famous Microprose game of Civilization"
+arch=('x86_64')
+url="http://www.freeciv.org/"
+license=('GPL2')
+depends=('curl' 'gtk3' 'lua' 'qt5-base' 'sdl2_gfx' 'sdl2_image' 'sdl2_mixer' 'sdl2_ttf')
+makedepends=('python')
+conflicts=('freeciv')
+provides=('freeciv')
+source=("git+https://github.com/freeciv/freeciv.git")
+sha256sums=('SKIP')
+
+pkgver() {
+    cd ${_basename}
+
+    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+build() {
+    cd ${_basename}
+
+    ./autogen.sh \
+        --prefix=/usr \
+        --sysconfdir=/etc \
+        --enable-fcdb=sqlite3 \
+        --enable-client=all \
+        --enable-gitrev \
+        --enable-aimodules=yes \
+        --enable-shared \
+        --enable-sdl-mixer \
+        --enable-fcmp=all \
+        --enable-sys-lua
+
+    make
+}
+
+package() {
+    cd ${_basename}
+
+    make DESTDIR="${pkgdir}" install
+}