Initial build (1.2.0)

3 files changed, 70 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..f35e7e6e58f8
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,17 @@
+pkgbase = funzzy-git
+	pkgdesc = A lightweight generic purpose file watcher
+	pkgver = 1.2.0.r9.g5a92558
+	pkgrel = 1
+	url = https://github.com/cristianoliveira/funzzy
+	arch = any
+	license = MIT
+	makedepends = git
+	makedepends = cargo
+	depends = glibc
+	depends = gcc-libs
+	provides = funzzy=1.2.0
+	conflicts = funzzy
+	source = funzzy::git+https://github.com/cristianoliveira/funzzy.git
+	sha256sums = SKIP
+
+pkgname = funzzy-git
diff --git a/.gitignore b/.gitignore
new file mode 100644
index 000000000000..018a3de08144
--- /dev/null
+++ b/.gitignore
@@ -0,0 +1,4 @@
+*
+!PKGBUILD
+!.SRCINFO
+!.gitignore
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..efec726f30b0
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,49 @@
+# Maintainer: vitaliikuzhdin <vitaliikuzhdin@gmail.com>
+
+_pkgname="funzzy"
+pkgname="${_pkgname}-git"
+pkgver=1.2.0.r9.g5a92558
+pkgrel=1
+pkgdesc="A lightweight generic purpose file watcher"
+arch=('any')
+url="https://github.com/cristianoliveira/${_pkgname}"
+license=('MIT')
+depends=('glibc' 'gcc-libs')
+makedepends=('git' 'cargo')
+provides=("${_pkgname}=${pkgver%%.r*}")
+conflicts=("${_pkgname}")
+_pkgsrc="${_pkgname}"
+source=("${_pkgsrc}::git+${url}.git")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd "${_pkgsrc}"
+  git describe --long --tags --abbrev=7 | sed 's/v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+prepare() {
+  cd "${srcdir}/${_pkgsrc}"
+  export RUSTUP_TOOLCHAIN=stable
+  cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
+}
+
+build() {
+  cd "${srcdir}/${_pkgsrc}"
+  export RUSTUP_TOOLCHAIN=stable
+  export CARGO_TARGET_DIR=target
+  cargo build --frozen --release --all-features
+}
+
+check() {
+  cd "${srcdir}/${_pkgsrc}"
+  export RUSTUP_TOOLCHAIN=stable
+  cargo test --frozen --all-features
+}
+
+package() {
+  cd "${srcdir}/${_pkgsrc}"
+  install -Dm755 "target/release/${_pkgname}" "${pkgdir}/usr/bin/${_pkgname}"
+  install -Dm755 "target/release/fzz" "${pkgdir}/usr/bin/fzz"
+  install -Dm644 "README.md" "${pkgdir}/usr/share/doc/${_pkgname}/README.md"
+  install -Dm644 "LICENSE" "${pkgdir}/usr/share/licenses/${_pkgname}/LICENSE"
+}