Update source download URL, modernize PKGBUILD

1 files changed, 45 insertions, 39 deletions

diff --git a/PKGBUILD b/PKGBUILD
index d2ecc3f5bfbe..76f9659ebf61 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -4,10 +4,10 @@
 # Contributor: Eric Forgeot < http://ifiction.free.fr >
 pkgname=gargoyle
 pkgver=2011.1
-pkgrel=4
+pkgrel=5
 pkgdesc="Interactive Fiction multi-interpreter that supports all major IF formats."
 arch=('i686' 'x86_64' 'armv6h')
-url="https://code.google.com/p/garglk/"
+url="http://ccxvii.net/gargoyle/"
 #alternative url="http://ccxvii.net/gargoyle/"
 license=('GPL')
 depends=('gtk2' 'sdl_mixer' 'sdl_sound' 'libvorbis' 'freetype2')
@@ -18,60 +18,66 @@ conflicts=('gargoyle-mod')
 replaces=('gargoyle-mod')
 #backup=()
 groups=(inform)
-source=("https://garglk.googlecode.com/files/$pkgname-$pkgver-sources.zip" \
+source=("https://github.com/garglk/garglk/archive/stable-${pkgver}.tar.gz" \
 	"gargoyle.sh" \
 	"gargoyle.install" \
 	"gargoyle.xml")
 install=${pkgname}.install
-sha512sums=('65159580cf3494944f841c44320135580557258e37ad5523ae3ea30555c19834a2793231a8e42c217e5c1d055d50ed6a20d372d6302e880a2818bc4ea59b226f'
+sha512sums=('3d2eb71e34b9faaace63963b55dddb61f81cfb1f3d42918036d942ffa0e59ca7f8a9747b1059230c32cfd8d467e09aae88befac1dd77723c2edfcb5acf8d4fa8'
             'fbfd04e6d62e469b62263f1fb92b314e825784982be3be9f0e506fe6ff7d367704db907c88ec60fc492f35eaa3548fc3a65fd67d8c4c2be7e35ed87a6c9c3489'
             '1fa602865745c1c9801178ee9b24be86215f2af4f9ee3f4f3b3c0606a87aba32a67c9c5343b481332c8fc97ff6c1a5e447f074d116c0cc5b255af35098096e6e'
             'c9924abc48b6dc5025fb83c040a3bdd2a324302d67683645a4fd1d1f3bcfe92c58a9db71c1e41a26afe8a3144e1cdafbc060df2261d93ddac29a9144ae22db71')
 
+prepare() {
+	cd "${srcdir}/garglk-stable-${pkgver}"
+	# Remove hardcoded optimisation and replace it with our CFLAGS	
+	sed -i "s|OPTIM = -O2 ;|OPTIM = ${CFLAGS} ;|" Jamrules
+	# Required to build with gcc 5
+	sed -i "s|SubDirCcFlags -DSMART_TOKENISER |SubDirCcFlags -fgnu89-inline -DSMART_TOKENISER |" terps/Jamfile
+}
+
 build() {
-  cd $srcdir
-  # Remove hardcoded optimisation and replace it with our CFLAGS	
-  sed -i "s|OPTIM = -O2 ;|OPTIM = ${CFLAGS} ;|" $srcdir/Jamrules
-  # Required to build with gcc 5
-  sed -i "s|SubDirCcFlags -DSMART_TOKENISER |SubDirCcFlags -fgnu89-inline -DSMART_TOKENISER |" $srcdir/terps/Jamfile
-  jam #|| return 1 # redundant? would be invoked when jam crashed but error code != 0 should crash build() anyway...
-  jam install #|| return 1 # ditto
+	cd "${srcdir}/garglk-stable-${pkgver}"
+	jam
+	jam install
 }
 
 package() {
-  cd $srcdir
-  # Install proper IF-reading binaries
-  install -dm755 $pkgdir/usr/bin/gargoyle-bins
-  install -m755 $srcdir/build/dist/* $pkgdir/usr/bin/gargoyle-bins/
-  ## hurr, durr, I'm dumb and dirty, gotta clean myself
-  rm $pkgdir/usr/bin/gargoyle-bins/libgarglk.so
+	local gsrcdir="${srcdir}/garglk-stable-${pkgver}"
+	cd "$gsrcdir"
+
+	# Install proper IF-reading binaries
+	install -dm755 "$pkgdir/usr/bin/gargoyle-bins"
+	install -m755 "$gsrcdir"/build/dist/* "$pkgdir/usr/bin/gargoyle-bins/"
+	## hurr, durr, I'm dumb and dirty, gotta clean myself
+	rm "$pkgdir/usr/bin/gargoyle-bins/libgarglk.so"
 
-  # Install libgarglk library
-  install -dm755 $pkgdir/usr/lib
-  install -m755 $srcdir/build/dist/libgarglk.so $pkgdir/usr/lib
+	# Install libgarglk library
+	install -dm755 "$pkgdir/usr/lib"
+	install -m755 "$gsrcdir/build/dist/libgarglk.so" "$pkgdir/usr/lib"
 
-  # Install a launching shell script
-  install -m755 $srcdir/gargoyle.sh $pkgdir/usr/bin/gargoyle
+	# Install a launching shell script
+	install -m755 "$srcdir/gargoyle.sh" "$pkgdir/usr/bin/gargoyle"
 
-  # Install default config
-  install -dm755 $pkgdir/etc
-  install -m755 $srcdir/garglk/garglk.ini $pkgdir/etc
+	# Install default config
+	install -dm755 "$pkgdir/etc"
+	install -m755 "$gsrcdir/garglk/garglk.ini" "$pkgdir/etc"
 
-  # Install desktop icons
-  install -dm755 $pkgdir/usr/share/pixmaps
-  install -m644 $srcdir/garglk/gargoyle-house.png $pkgdir/usr/share/pixmaps/${pkgname}.png
+	# Install desktop icons
+	install -dm755 "$pkgdir/usr/share/pixmaps"
+	install -m644 "$gsrcdir/garglk/gargoyle-house.png" "$pkgdir/usr/share/pixmaps/${pkgname}.png"
 
-  # Install gargoyle xdg desktop entry
-  ## before that, patch the icon path since we renamed it earlier
-  sed -i 's|Icon=gargoyle-house.png|Icon=gargoyle.png|' $srcdir/garglk/${pkgname}.desktop
-  ## link it with x-interactive-fiction mimetype
-  echo "MimeType=application/x-interactive-fiction">>$srcdir/garglk/${pkgname}.desktop
-  ## and then install it. Yay~ :3
-  install -dm755 $pkgdir/usr/share/applications
-  install -m644 $srcdir/garglk/${pkgname}.desktop $pkgdir/usr/share/applications/${pkgname}.desktop
+	# Install gargoyle xdg desktop entry
+	## before that, patch the icon path since we renamed it earlier
+	sed -i 's|Icon=gargoyle-house.png|Icon=gargoyle.png|' "$gsrcdir/garglk/${pkgname}.desktop"
+	## link it with x-interactive-fiction mimetype
+	echo "MimeType=application/x-interactive-fiction" >> "$gsrcdir/garglk/${pkgname}.desktop"
+	## and then install it. Yay~ :3
+	install -dm755 "$pkgdir/usr/share/applications"
+	install -m644 "$gsrcdir/garglk/${pkgname}.desktop" "$pkgdir/usr/share/applications/${pkgname}.desktop"
 
-  # Install mimetype
-  install -dm755 $pkgdir/usr/share/mime/packages
-  install -m644 $srcdir/gargoyle.xml $pkgdir/usr/share/mime/packages/
+	# Install mimetype
+	install -dm755 "$pkgdir/usr/share/mime/packages"
+	install -m644 "$srcdir/gargoyle.xml" "$pkgdir/usr/share/mime/packages/"
 }