Initial commit

2 files changed, 59 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..e8c29030fa64
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,18 @@
+pkgbase = garuda-downloader-git
+	pkgdesc = Installation image downloader for Garuda Linux with support for delta downloads
+	pkgver = r17.5a2d5af
+	pkgrel = 1
+	url = https://gitlab.com/garuda-linux/applications/garuda-downloader
+	arch = x86_64
+	license = GPL
+	makedepends = qt5-tools
+	makedepends = cmake
+	makedepends = git
+	depends = qt5-base
+	provides = garuda-downloader
+	conflicts = garuda-downloader
+	source = garuda-downloader-git::git+https://gitlab.com/garuda-linux/applications/garuda-downloader
+	md5sums = SKIP
+
+pkgname = garuda-downloader-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..c8cb5be0ebde
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,41 @@
+# Maintainer: TNE <totallynotelite@gmail.com>
+
+pkgname=garuda-downloader-git
+pkgver=r17.5a2d5af
+pkgrel=1
+pkgdesc="Installation image downloader for Garuda Linux with support for delta downloads"
+arch=('x86_64')
+url="https://gitlab.com/garuda-linux/applications/garuda-downloader"
+license=('GPL')
+depends=('qt5-base')
+makedepends=('qt5-tools' 'cmake' 'git')
+provides=('garuda-downloader')
+conflicts=('garuda-downloader')
+source=("$pkgname::git+$url")
+md5sums=('SKIP')
+
+pkgver() {
+    cd "$pkgname"
+    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+prepare() {
+    cd "$pkgname"
+    git submodule update --init --recursive
+}
+
+build() {
+    cmake -B build -S "$pkgname" \
+        -DCMAKE_BUILD_TYPE='Release' \
+        -DCMAKE_INSTALL_PREFIX='/usr' \
+        -Wno-dev
+    make -C build
+}
+
+package() {
+    make -C build DESTDIR="$pkgdir" install
+    
+    cd "$pkgname"
+    install -Dm0644 resources/garuda.svg "$pkgdir/usr/share/pixmaps/garuda-downloader.svg"
+    install -Dm0644 resources/Garuda-Downloader.desktop "$pkgdir/usr/share/applications/Garuda-Downloader.desktop"
+}